Question

我编写了自己开发的串行端口类，为简单起见，我使用了阻塞/同步/ 不重叠。我浏览了所有MSDN文档，这对我来说是两难的。

我从端口打开，传输或接收字节没有任何问题。所有操作都是同步，并且没有线程复杂性。

function TSerialPort.Open: Boolean;
var
  h: THandle;
  port_timeouts: TCommTimeouts;
  dcb: TDCB;
begin
  Result := False;

  if Assigned(FHandleStream) then
  begin
    // already open
    Exit(True);
  end;

  h := CreateFile(PChar('\\?\' + FComPort),
                  GENERIC_WRITE or GENERIC_READ, 0, nil, OPEN_EXISTING, FILE_ATTRIBUTE_NORMAL, 0);

  // RaiseLastOSError();
  if h <> INVALID_HANDLE_VALUE then
  begin
    {
      REMARKS at https://docs.microsoft.com/en-us/windows/desktop/api/winbase/ns-winbase-_commtimeouts
      If an application sets ReadIntervalTimeout and ReadTotalTimeoutMultiplier to MAXDWORD and
      sets ReadTotalTimeoutConstant to a value greater than zero and less than MAXDWORD, one
      of the following occurs when the ReadFile function is called:

      * If there are any bytes in the input buffer, ReadFile returns immediately with the bytes in the buffer.
      * If there are no bytes in the input buffer, ReadFile waits until a byte arrives and then returns immediately.
      * If no bytes arrive within the time specified by ReadTotalTimeoutConstant, ReadFile times out.
    }

    FillChar(port_timeouts, Sizeof(port_timeouts), 0);
    port_timeouts.ReadIntervalTimeout := MAXDWORD;
    port_timeouts.ReadTotalTimeoutMultiplier := MAXDWORD;
    port_timeouts.ReadTotalTimeoutConstant := 50; // in ms
    port_timeouts.WriteTotalTimeoutConstant := 2000; // in ms

    if SetCommTimeOuts(h, port_timeouts) then
    begin
      FillChar(dcb, Sizeof(dcb), 0);
      dcb.DCBlength := sizeof(dcb);

      if GetCommState(h, dcb) then
      begin
        dcb.BaudRate := FBaudRate;                            //  baud rate
        dcb.ByteSize := StrToIntDef(FFrameType.Chars[0], 8);  //  data size
        dcb.StopBits := ONESTOPBIT;                           //  1 stop bit
        dcb.Parity   := NOPARITY;
        case FFrameType.ToUpper.Chars[1] of
          'E': dcb.Parity   := EVENPARITY;
          'O': dcb.Parity   := ODDPARITY;
        end;

        dcb.Flags := dcb_Binary or dcb_Parity or dcb_ErrorChar or
                     (DTR_CONTROL_ENABLE shl 4) or (RTS_CONTROL_ENABLE shl 12);

        dcb.ErrorChar := '?'; // parity error will be replaced with this char

        if SetCommState(h, dcb) then
        begin
          FHandleStream := THandleStream.Create(h);
          Result := True;
        end;
      end;
    end;

    if not Result then
    begin
      CloseHandle(h);
    end;
  end;
end;

function TSerialPort.Transmit(const s: TBytes): Boolean;
var
  len: NativeInt;

begin
  Result := False;
  len := Length(s);

  if Assigned(FHandleStream) and (len > 0) then
  begin
    // total timeout to transmit is 2sec!!
    Result := (FHandleStream.Write(s, Length(s)) = len);
  end;
end;

function TSerialPort.Receive(var r: Byte): Boolean;
begin
  Result := False;

  if Assigned(FHandleStream) then
  begin
    // read timeout is 50ms
    Result := (FHandleStream.Read(r, 1) = 1);
  end;
end;

我的问题开始于关闭端口。在进行所有通信之后，当我尝试关闭串行端口时，我的应用程序完全挂在CloseHandle（）API上。这是随机发生的。因为我使用同步模式，所以这对我来说毫无意义，不能有任何挂起的操作。当我请求关闭时，必须简单地关闭手柄。

我在Google和堆栈溢出中搜索了问题。很多人都遇到过类似的问题，但是大多数人都与.NET串行端口驱动程序及其异步模式操作有关，而我没有。

还有一些人忘记正确设置超时，他们在完全正常的ReadFile和WriteFile API上遇到阻塞问题。但这又不是我的问题，我已经设置了CommTimeouts，如MSDN注释中所述。

function TSerialPort.Close: Boolean;
var
  h: THandle;

begin
  Result := True;

  if Assigned(FHandleStream) then
  begin
    h := FHandleStream.Handle;
    FreeAndNil(FHandleStream);

    if h <> INVALID_HANDLE_VALUE then
    begin
      //PurgeComm(h, PURGE_TXABORT or PURGE_RXABORT or PURGE_TXCLEAR or PURGE_RXCLEAR); // didn't help
      //ClearCommError(h, PDWORD(nil)^, nil);  // didn't help
      //CancelIO(h);  // didn't help
      Result := CloseHandle(h); <------------ hangs here
    end;
  end;
end;

Microsoft论坛上的某些人建议在其他线程中调用CloseHandle（）。我也尝试过。但是那个时候它在尝试释放我创建的AnonymousThread时挂起了。即使我默认将FreeOnTerminate：= true保留为默认值，它也会挂起，并且我会收到Delphi的内存泄漏报告。

挂起时另一个麻烦的问题是，我必须完全关闭Delphi IDE并重新打开。否则，由于仍使用exe，因此无法再次编译代码。

function TSerialPort.Close: Boolean;
var
  h: THandle;
  t: TThread;
  Event: TEvent;

begin
  Result := True;

  if Assigned(FHandleStream) then
  begin
    h := FHandleStream.Handle;
    FreeAndNil(FHandleStream);

    if h <> INVALID_HANDLE_VALUE then
    begin
      PurgeComm(h, PURGE_TXABORT or PURGE_RXABORT or PURGE_TXCLEAR or PURGE_RXCLEAR);
      Event := TEvent.Create(nil, False, False, 'COM PORT CLOSE');
      t := TThread.CreateAnonymousThread(
        procedure()
        begin
          CloseHandle(h);
          If Assigned(Event) then Event.SetEvent();
        end);

      t.FreeOnTerminate := False;
      t.Start;
      Event.WaitFor(1000);
      FreeAndNil(t);  // <---------- that time it hangs here, why??!!
      FreeAndNil(Event);
    end;
  end;
end;

在笔记本中，我使用的是FDTI的USB到串行端口转换器。有人说这是因为FDTI驱动程序。但是，我正在使用由Microsoft Windows硬件兼容性发布者签名的所有Microsoft驱动程序。我的系统中没有第三方驱动程序。但是，当我断开USB适配器的连接时，CloseHandle API会自行冻结。有人报告说，即使是主板上内置的本机串行端口也存在相同的问题。

到目前为止，我无法解决问题。高度赞赏任何帮助或解决方法。

谢谢。

Answer 1

此问题与FTDI USB-Serial转换器驱动程序有关。它无法正确处理硬件流控制，有时会挂在CloseHandle调用中。

要解决此问题，请手动实施硬件流控制。在C ++中（不确定如何在Delphi中完成），请设置以下DCB结构字段，以允许手动控制RTS行：

// Assuming these variables are defined in the header
HANDLE m_hComm; // Comm port handle.
DCB m_dcb;      // DCB comm port settings.

// Put these settings in the DCB structure.
m_dcb.fRtsControl = RTS_CONTROL_ENABLE;
m_dcb.fOutxCtsFlow = TRUE;

然后使用

EscapeCommFunction(m_hComm, CLRRTS); // Call this before calling WriteFile.

和

EscapeCommFunction(m_hComm, SETRTS); // Call this after Write is complete.

在您的情况下，因为它是同步的-您只需用这2个调用包装对WriteFile的每个调用即可。如果使用的是异步方法（例如我的情况），请在WriteFile调用的重叠结构中获取完成事件后，使用SETRTS调用该方法。

在执行此操作之前，它一直冻结，因为我们正在使用12个串行端口，并且解锁端口的唯一方法是重新启动计算机。现在可以像手动控制的超级按钮一样工作，此后从未冻结过。

请记住，某些USB串行设备（甚至是不同版本的FTDI）可能会使RTS线反转！因此，如果上述方法不起作用，请尝试使用SETRTS将行设置为低电平，然后使用CLRRTS将其设置为高电平。

编辑：如果您有权使用Windows XP计算机，请使用portmon工具查看RTS行的状态，这样您将知道它是否被反转，或者是否正在获取命令。 / p>

非重叠的串行端口挂在CloseHandle

1 个答案: