Question

下面是我拥有的数据集：

:project#1   :hasRevision        :revision#1
:revision#1  :hasRevisionNumber  1 
:project#1   :hasRevision        :revision#2
:revision#2  :hasRevisionNumber  2
:project#1   :hasRevision        :revision#3
:revision#3  :hasRevisionNumber  3
:revision#1  :committed          :A1
:A1          :hasId              1
:revision#2  :committed          :A2
:A2          :hasId              2
:revision#3  :reverted           :A1

用例：

需要获取每个修订版中提交的属性。
-如果用户要求输入:revision#1，则应返回A1。
-如果用户要求输入:revision#2，则应返回A1和A2。
-如果用户要求:revision#3，则仅返回A2，因为A1中:reverted是:revision#3。

我能提出的最接近的查询在下面不起作用：

select ?attribute ?id WHERE { 
    :project1  :hasRevision       ?revision . 
    ?revision  :hasRevisionNumber ?revNum ; 
               :committed         ?attribute . 
   ?attribute  :hasId             ?id . 
   FILTER NOT EXISTS { ?revision :reverted ?attribute } 
   FILTER ( ( ?revNum <= 3 && ?revNum > 0 ) && ?id in (1,2) ) 
}

实际输出：

A1 & A2

预期输出：

A2

我了解这个问题。无法提出正确的查询。你们中的任何一个都可以帮忙。

先谢谢了。

Answer 1

在FILTER NOT EXISIT中使用其他变量，例如

FILTER NOT EXISTS { ?otherRevision :reverted ?attribute }

编辑：在@Linz附加注释之后，添加一个过滤器以仅查找修订号较小的修订。

prefix : <http://base.org/>
select ?attribute ?id WHERE { 
    bind (3 as ?targetRevisionNum )
    :project1  :hasRevision       ?revision . 
    ?revision  :hasRevisionNumber ?revNum ; 
               :committed         ?attribute . 
   ?attribute  :hasId             ?id . 
    FILTER NOT EXISTS { 
        ?other :reverted ?attribute . 
        ?other :hasRevisionNumber ?otherRevNum .
        filter (?otherRevNum <= ?targetRevisionNum )
    } 
   FILTER ( ( ?revNum <= ?targetRevisionNum && ?revNum > 0 ) && ?id in (1,2) ) 
}

Answer 2

找到了解决方法。
一个对象只能是:committed和:reverted一次。如此使用具有聚合功能的having根据从“ {revision”到“ object”之间的关系计数进行过滤，我的最终查询如下：

prefix : <http://test.org/> 

select  ?attribute WHERE { 

        :project1  :hasRevision       ?revision . 
        ?revision  :hasRevisionNumber ?revNum ; 
                   ?s   ?attribute .
        ?attribute :hasId ?id;
        FILTER ( ( ?revNum <= 3 && ?revNum > 0 ) && ?id in (1,2) )  

}  
group by ?attribute 
having (count(?attribute) < 2 )

输出：

attribute
<http://test.org/A2>

如果有人能找到我一个更好的查询，我将感到高兴。谢谢大家！

RDF SPARQL查询-查找不属于两个条件的元组（SQL中的LEFT JOIN）

用例：

实际输出：

预期输出：

2 个答案: