使用表格
t:([]c1: 3 4 7 2 4.0;c2: 2 8 10 1 9.0;c3:5 8 13 2 11.0)
c1 c2 c3
3 2 5
4 8 8
7 10 13
2 1 2
4 9 11
我需要更新3个新列(c1M,c2M,c3M)，其中：
第一行：
c1M:avg(c1,c2,c3) c2M:avg(c1,c2) c3M:c3 其他行：
c1M:avg(c1,c2,c3) c2M:avg(prev c1M,prev c2M) c3M:max(c3,c1M,c2M) 我可以使用
进行第一行t:update c1M:avg(c1,c2,c3),c2M:avg(c1,c2),c3M:c3 from t where i=0
c1 c2 c3 c1M c2M c3M
3 2 5 3.3 2.5 5
4 8 8 0n 0n 0N
7 10 13 0n 0n 0N
2 1 2 0n 0n 0N
4 9 11 0n 0n 0N
不确定如何进行艰苦的工作。我尝试过类似的事情：
update c1M:avg(c1;c2;c3),c2M:avg(prev c1M;prev c2M),c3M:c3|c1M|c2M from t where i>0
但是没有运气。
此示例的结果应为：
c1 c2 c3 c1M c2M c3M
3 2 5 3.3 2.5 5.0
4 8 8 6.7 2.9 8.0
7 10 13 10 4.8 13.0
2 1 2 1.7 7.4 7.4
4 9 11 8.0 4.5 11.0
有人可以帮我吗？
答案 0 :(得分：5)
向量计算中的KDB +比迭代时要快得多。因此，一种可能更快的方法是使用副词仅在c2M列上进行迭代，因为这是唯一需要该列中的上一个值的方法。 我认为您可能正在寻找的是：
q)\ts:1000 ({update c3M:max(c3;c1M;c2M),c2M:c2M^avg(prev c1M;prev
c2M),c1M:c1M^avg(c1;c2;c3) from x}/)[update
c1M:avg(c1,c2,c3),c2M:avg(c1,c2),c3M:c3 from t where i=0]
53 7568
q)\ts:1000 update c3M:c3 from (update c3M:max(c3;c1M;c2M) from update c2M:
{avg x,y}\[first c2;first[c1],1_prev c1M] from update c1M:avg(c1;c2;c3) from
t) where i=0
11 6896
这比遍历整个表并执行计算要快，就像这样：
undefined答案 1 :(得分：1)
我认为您在这里寻找的已经结束： http://code.kx.com/q/ref/adverbs/#over
它将遍历表的每一行
q)({update c3M:max(c3;c1M;c2M),c2M:c2M^avg(prev c1M;prev c2M),c1M:c1M^avg(c1;c2;c3) from x}/)[update c1M:avg(c1,c2,c3),c2M:avg(c1,c2),c3M:c3 from t where i=0]
c1 c2 c3 c1M c2M c3M
--------------------
3 2 5 3.3 2.5 5
4 8 8 6.7 2.9 8
7 10 13 10 4.8 13
2 1 2 1.7 7.4 7.4
4 9 11 8 4.5 11
答案 2 :(得分：1)
q) nt:update c1m:avg(c1;c2;c3) from t
q) nt:update c2m:-1_({avg x,y}\[avg[c1[0],c2[0]],c1m]) from nt
q) nt:update c3m:(c3[0],1_max(c3;c1m;c2m)) from nt
答案 3 :(得分：1)
另一种方法，可能不是最快的方法，而是较小的代码足迹
q){y,`c1M`c2M`c3M!a,max y[`c3],a:(avg y;avg y[`c1`c2]^x`c1M`c2M)}\[t@-1;t]
c1 c2 c3 c1M c2M c3M
-----------------------------------
3 2 5 3.333333 2.5 5
4 8 8 6.666667 2.916667 8
7 10 13 10 4.791667 13
2 1 2 1.666667 7.395833 7.395833
4 9 11 8 4.53125 11