Question

假设我们正在编写一个lambda演算的实现，作为其中的一部分，我们希望能够选择一个新的非冲突名称：

record Ctx where
  constructor MkCtx
  bindings : List String

emptyCtx : Ctx
emptyCtx = MkCtx []

addCtx : String -> Ctx -> Ctx
addCtx name = record { bindings $= (name ::) }

pickName : String -> Ctx -> (String, Ctx)
pickName = go Z
  where
    mkName : Nat -> String -> String
    mkName Z name = name
    mkName n name = name ++ show n

    go n name ctx = let name' = mkName n name in
                    if name' `elem` bindings ctx
                       then go (S n) name ctx
                       else (name', addCtx name' ctx)

Idris总体检查器认为pickName由于go中的递归路径而不是总计，因此是正确的：确实，总体证明不依赖于语法上变小的任何项，而是依赖于观察到，如果bindings具有k个元素，则只需不超过k + 1个递归调用即可找到一个新名称。但是如何用代码表达呢？

我还倾向于外部验证，即首先编写一个函数，然后编写（具有类型检查，但从不执行）具有正确属性的证明。在这种情况下，pickName是否可以总计？

受@HTNW的启发，正确的方法似乎只是使用Vect而不是列表。从向量中删除元素将使其大小（以类型表示）在语法上更小，从而无需自己证明。因此，pickName的（稍微重构的）版本将是

pickName : String -> Vect n String -> String
pickName name vect = go Z vect
  where
    mkName : Nat -> String
    mkName Z = name
    mkName n = name ++ show n

    go : Nat -> Vect k String -> String
    go {k = Z} n _ = mkName n
    go {k = (S k)} n vect' =
      let name' = mkName n in
      case name' `isElem` vect' of
           Yes prf => go (S n) $ dropElem vect' prf
           No _ => name'

Answer 1

在序曲中，我们有：

Smaller x y = size x `LT` size y
instance Sized (List a) where size = length
sizeAccessible : Sized a => (x : a) -> Accessible Smaller x
accRec : (step : (x : a) -> ((y : a) -> rel y x -> b) -> b) ->
         (z : a) -> Accessible rel z -> b

accRec允许您以编译器可以理解为total的方式使用“非标准递归模式”。它基本上是fix : ((a -> b) -> (a -> b)) -> (a -> b)，只是开放递归函数必须传递一个额外的证明项来证明递归参数在某种程度上“更小”。 Accessible参数决定了使用的递归模式。这是简单的“减小Nat大小”样式。最好使用sizeRec代替accRec + sizeAccessible，但我无法使其正常工作。随时以“正确”的方式进行编辑。

函数的每次迭代，都可以删除该名称。

delFirst : DecEq a => (x : a) -> (xs : List a)
        -> Maybe (ys : List a ** length xs = S (length ys))
delFirst _ [] = Nothing
delFirst x (y :: xs) with (decEq x y)
  delFirst x (x :: xs) | Yes Refl = Just (xs ** Refl)
  delFirst x (y :: xs) | No _ with (delFirst x xs)
    | Nothing = Nothing
    | Just (ys ** prf) = Just (x :: ys ** cong prf)

现在，您可以在pickName中使用开放的，有根据的递归：

pickName : String -> Ctx -> (String, Ctx)
pickName s ctx = let new = go s (bindings ctx) Z
                  in (new, addCtx new ctx)
  where mkName : Nat -> String -> String
        mkName Z name = name
        mkName n name = name ++ show n
        ltFromRefl : n = S m -> LT m n
        ltFromRefl Refl = lteRefl
        go : String -> List String -> Nat -> String
        go name binds = accRec (\binds, rec, n =>
                          let name' = mkName n name
                           in case delFirst name' binds of
                                   Nothing => name'
                                   Just (binds' ** prf) => rec binds' (ltFromRefl prf) (S n)
                          ) binds (sizeAccessible binds)

Nat -> a与Stream a是同一件事，因此IMO会更好一些：

findNew : DecEq a => (olds : List a) -> (news : Stream a) -> a
findNew olds = accRec (\olds, rec, (new :: news) =>
                        case delFirst new olds of
                             Nothing => new
                             Just (olds' ** prf) => rec olds' (ltFromRefl prf) news
                      ) olds (sizeAccessible olds)
  where ltFromRefl : n = S m -> LT m n
        ltFromRefl Refl = lteRefl

pickName : String -> Ctx -> (String, Ctx)
pickName name ctx = let new = findNew (bindings ctx)
                                      (name :: map ((name ++) . show) (iterate S 1))
                     in (new, addCtx new ctx)

我认为，这可以理解一种直觉，即如果您有无限的名称供应，但是只有有限的旧名称，那么您肯定会有无限的新名称。

（而且，代码中的逻辑似乎是错误的。是否翻转了if的分支？）

证明一个函数最多可以进行n次递归调用

1 个答案: