Question

我已经创建了QML图表

ChartView {
    id: chart
    anchors.fill: parent
    antialiasing: true
    ValueAxis {
        id: axisY
        tickCount: 3
    }
    DateTimeAxis {
        id: xTime
    }
    SplineSeries {
        id: chartseries
        pointsVisible: true

        pointLabelsVisible: false
        useOpenGL: true
        axisX: xTime
        axisY: axisY
    }
}

我还将在每个月初添加到图表。刻度点上的工具提示正确。在X轴上，Qt本身的行为与所执行的相同。如何手动调整

 Xaxis->setTickCount(commonmap.size());
QMap<qint64,double>::const_iterator i = commonmap.constBegin();
while (i != commonmap.constEnd())
{
  splineseries->append(i.key(),i.value());
  ++i;
}

Answer 1

我看到您将DateTimeAxis的tickCount设置为系列中的样本数，所以Qt所做的是除以最大和最小值，然后除以时间，计算得出大约31天，我们可以将DateTimeAxis的形式修改为“ MMM yyyy dd hh：mm：ss”：

所以显示的日期不是月份，而是间隔相等的时间，只有2月28天不会显示该日期。

如果要显示2月，则必须在tickCount上放置一个较大的值，但它还会生成更多日期。不幸的是，当前不可能以不规则的方式放置刻度线，例如月份的天数。

Answer 2

我已经找到了解决这个问题的方法（可能不是正确的方法……但是可以解决）实现解决方案的步骤-

查找上个月（例如6月30日）的最后日期
setMax日期QDateTimeAxis。

之所以起作用，是因为Qt将开始日期和结束日期之间的天数平均分配，并基于刻度数在X轴上进行分配。

使用上述问题中的值将获得图表，如图

所示。

[

Xaxis->setMin(QDateTime::fromMSecsSinceEpoch(commonmap.firstKey()));
Xaxis->setMax(getLastDate());

getLastDate()
{
   QDate firstdate = 
   QDateTime::fromMSecsSinceEpoch(commonmap.lastKey()).date();
   int month =  firstdate.month();
   int day = firstdate.day();
   int addday = 0;
   switch (month) {
    case 1:
    case 3:
    case 5:
    case 7:
    case 8:
    case 10:
    case 12:
       addday = 31- day;
      break;
    case 4:
    case 6:
    case 9:
    case 11:
       addday = 30- day;
     break;
    case 2:
        if(firstdate.isLeapYear(firstdate.year()))
        {
            addday = 29- day;
        }
        else
       {
          addday = 28- day;
       }
       break;

   }

return (QDateTime::fromMSecsSinceEpoch(commonmap.lastKey()).addDays(addday));
 }

Answer 3

如@eyllanesc在他的回答中所述，无法使用DateTimeAxis来获取要显示的内容。

这里有一些代码可以帮助通过使用CategoryAxis来产生一些东西。

注意：在我的示例中，数据是用QML创建和格式化的，但是您可以在实际上可能是数据的C ++部分中进行操作。

import QtQuick 2.9
import QtCharts 2.2

Item {
    id: root
    width: 1280
    height: 720

    ListModel {
        id: data

        function toMsecsSinceEpoch(date) {
            var msecs = date.getTime();
            return msecs;
        }

        Component.onCompleted: {
            var minDate = data.get(0).x;
            var maxDate = data.get(0).x;
            var minValue = data.get(0).y;
            var maxValue = data.get(0).y;

            // Find the minimum and maximum values.
            // Fill the SplineSeries data.
            for (var i = 0 ; i < data.count ; i++) {
                if (data.get(i).x < minDate)
                    minDate = data.get(i).x;
                if (data.get(i).x > maxDate)
                    maxDate = data.get(i).x;
                if (data.get(i).y < minValue)
                    minValue = data.get(i).y;
                if (data.get(i).y > maxValue)
                    maxValue = data.get(i).y;
                chartseries.append(data.get(i).x, data.get(i).y);
            }

            // Fill the axis limits (x-axis and y-axis).
            axisY.min = Math.floor(minValue)
            axisY.max = Math.ceil(maxValue)
            xTime.min = minDate;
            xTime.max = maxDate;

            // Fill the CategoryAxis (x-axis).
            var dateReference = new Date(xTime.min);
            while (dateReference < xTime.max) {
                xTime.append(Qt.formatDate(dateReference, "MMM yyyy"), toMsecsSinceEpoch(new Date(dateReference.getFullYear(), dateReference.getMonth(), 1)));
                dateReference.setMonth(dateReference.getMonth() + 1);
            }
            xTime.append(Qt.formatDate(dateReference, "MMM yyyy"), toMsecsSinceEpoch(new Date(dateReference.getFullYear(), dateReference.getMonth(), 1)));
        }

        ListElement { x: 1514770200000; y: 40.311 }
        ListElement { x: 1517434200000; y: 40.4664 }
        ListElement { x: 1519853400000; y: 39.6276 }
        ListElement { x: 1522531803000; y: 39.6238 }
        ListElement { x: 1525123806000; y: 40.3 }
        ListElement { x: 1527802210000; y: 40.5638 }
    }

    ChartView {
        id: chart
        anchors.fill: parent
        antialiasing: true

        ValueAxis {
            id: axisY
            tickCount: 3
            min: 39
            max: 41
        }

        CategoryAxis {
            id: xTime
            labelsPosition: CategoryAxis.AxisLabelsPositionOnValue
        }

        SplineSeries {
            id: chartseries
            pointsVisible: true
            pointLabelsVisible: false
            useOpenGL: true
            axisX: xTime
            axisY: axisY
        }
    }
}

Qt图表（QML）日期时间轴缺少2月

3 个答案: