获取Vim中文档的实时单词计数

Question

我希望vim在状态栏中显示总文档字数（在其中显示当前行和字符号）。我在SO上遇到了类似的问题，并尝试了here和here提到的所有建议---这些都没有对我的状态栏产生任何影响。

为了明确地列举几个例子，我尝试将以下任何内容粘贴到~/.vimrc中（并且ofc随后重新启动了vim）：

function! CountNonEmpty()
    let l = 1
    let char_count = 0
    while l <= line("$")
        if len(substitute(getline(l), '\s', '', 'g')) > 3   
            let char_count += 1 
        endif
        let l += 1
    endwhile
    return char_count
endfunction

function WordCount()
  let s:old_status = v:statusmsg
  exe "silent normal g\<c-g>"
  let s:word_count = str2nr(split(v:statusmsg)[11])
  let v:statusmsg = s:old_status
  return s:word_count
endfunction  

" If buffer modified, update any 'Last modified: ' in the first 20 lines.
" 'Last modified: ' can have up to 10 characters before (they are retained).
" Restores cursor and window position using save_cursor variable.
function! LastModified()
  if &modified
    let save_cursor = getpos(".")
    let n = min([15, line("$")])
    keepjumps exe '1,' . n . 's#^\(.\{,10}LOC:\).*#\1' .
          \ ' ' . CountNonEmpty() . '#e'
    keepjumps exe '1,' . n . 's#^\(.\{,10}Word Count:\).*#\1' .
          \ ' ' . WordCount() . '#e'
    call histdel('search', -1)
    call setpos('.', save_cursor)
  endif
endfun 

OR

function WordCount()
  let s:old_status = v:statusmsg
  exe "silent normal g\<c-g>"
  let s:word_count = str2nr(split(v:statusmsg)[11])
  let v:statusmsg = s:old_status
  return s:word_count
endfunction
set statusline=wc:%{WordCount()}

OR

function! WordCount()
   let s:old_status = v:statusmsg
   let position = getpos(".")
   exe ":silent normal g\<c-g>"
   let stat = v:statusmsg
   let s:word_count = 0
   if stat != '--No lines in buffer--'
     let s:word_count = str2nr(split(v:statusmsg)[11])
     let v:statusmsg = s:old_status
   end
   call setpos('.', position)
   return s:word_count 
endfunction
set statusline=wc:%{WordCount()}

OR

let g:word_count="<unknown>"
fun! WordCount()
    return g:word_count
endfun
fun! UpdateWordCount()
    let s = system("wc -w ".expand("%p"))
    let parts = split(s, ' ')
    if len(parts) > 1
        let g:word_count = parts[0]
    endif
endfun

augroup WordCounter
    au! CursorHold * call UpdateWordCount()
    au! CursorHoldI * call UpdateWordCount()
augroup END

" how eager are you? (default is 4000 ms)
set updatetime=500

" modify as you please...
set statusline=%{WordCount()}\ words

或更多。正如我所说，没有效果。没有错误消息，没有视觉上可察觉的变化。我想可能是我遗漏了一个常见问题，但这是什么？

Answer 1

假设您的状态行已启用（set laststatus=2），则以下内容：

set statusline+=%{wordcount().words}\ words

完全符合您在Vim 7.4.1042及更高版本中的要求：

请参见:help wordcount()。

---

如果绝对需要向后兼容，则可以保证在Vim 7.x中可以使用以下功能，并且在较早版本中也可以使用：

function! WC()
    return len(split(join(getline(1,'$'), ' '), '\s\+'))
endfunction
set statusline+=%{WC()}\ words

不过，那些旧线程中的某些答案 可能更快或更聪明。

---

您对那些来自那些旧线程的函数的评论并没有改变您的状态行，这使我想知道问题出在所有这些旧答案中还是其他地方。也许……您没有状态行开头？

Answer 2

vim-airline中的字数

vim-airline针对许多文件类型提供了标准的字数统计，截至撰写本文时： asciidoc, help, mail, markdown, org, rst, tex ,text

如果vim-airline中未显示字数，则通常是由于无法识别的文件类型。例如，at least for now不能由vim-airline识别复合文件类型markdown.pandoc来进行字数统计。可以通过如下修改.vimrc来轻松地解决此问题：

let g:airline#extensions#wordcount#filetypes = '\vasciidoc|help|mail|markdown|markdown.pandoc|org|rst|tex|text'
set laststatus=2    " enables vim-airline.

\v语句将覆盖默认的g:airline#extensions#wordcount#filetypes变量。最后一行确保启用vim-airline。

如有疑问，在发出以下命令后将返回打开文件的&filetype：

:echo &filetype

这是一个元示例：