Vim中的快速字数统计功能

时间：2008-09-22 11:58:23

标签： vim

我正在尝试在vim状态行中显示实时字数。我这样做是通过在我的.vimrc中设置我的状态行并在其中插入一个函数。这个函数的想法是返回当前缓冲区中的字数。然后，此编号显示在状态行上。这应该很好地工作，因为状态线几乎在每个可能的机会更新，因此计数将始终保持“实时”。

问题是我当前定义的函数很慢，所以当它用于除最小文件之外的所有文件时，vim显然是缓慢的;由于这个功能经常执行。

总之，有没有人有一个聪明的技巧来产生一个快速计算当前缓冲区中的单词数并返回结果的函数？

17 个答案:

答案 0 :(得分：25)

我真的很喜欢迈克尔邓恩上面的回答，但我发现当我编辑时，它导致我无法访问最后一列。所以我对这个功能进行了一些小改动：

function! WordCount()
   let s:old_status = v:statusmsg
   let position = getpos(".")
   exe ":silent normal g\<c-g>"
   let stat = v:statusmsg
   let s:word_count = 0
   if stat != '--No lines in buffer--'
     let s:word_count = str2nr(split(v:statusmsg)[11])
     let v:statusmsg = s:old_status
   end
   call setpos('.', position)
   return s:word_count 
endfunction

我已将其包含在我的状态行中而没有任何问题：

:set statusline=wc:%{WordCount()}

答案 1 :(得分：23)

这是罗德里戈奎罗的想法的可用版本。它不会更改状态栏，而是还原statusmsg变量。

function WordCount()
  let s:old_status = v:statusmsg
  exe "silent normal g\<c-g>"
  let s:word_count = str2nr(split(v:statusmsg)[11])
  let v:statusmsg = s:old_status
  return s:word_count
endfunction

这似乎足够快，可以直接包含在状态行中，例如：

:set statusline=wc:%{WordCount()}

答案 2 :(得分：9)

保持当前行的计数以及其余缓冲区的单独计数。当您在当前行上键入（或删除）单词时，仅更新该计数，但显示当前行数和剩余缓冲区计数的总和。

当您更改行时，将当前行计数添加到缓冲区计数，计算当前行中的单词，a）设置当前行计数，b）从缓冲区计数中减去它。

定期重新计算缓冲区也是明智的（请注意，您不必一次计算整个缓冲区，因为您知道正在进行编辑的位置）。

答案 3 :(得分：4)

每当您停止输入一段时间（特别是updatetime毫秒）时，这将重新计算字数。

let g:word_count="<unknown>"
fun! WordCount()
    return g:word_count
endfun
fun! UpdateWordCount()
    let s = system("wc -w ".expand("%p"))
    let parts = split(s, ' ')
    if len(parts) > 1
        let g:word_count = parts[0]
    endif
endfun

augroup WordCounter
    au! CursorHold * call UpdateWordCount()
    au! CursorHoldI * call UpdateWordCount()
augroup END

" how eager are you? (default is 4000 ms)
set updatetime=500

" modify as you please...
set statusline=%{WordCount()}\ words

享受！

答案 4 :(得分：3)

所以我写了：

func CountWords()
    exe "normal g\"
    let words = substitute(v:statusmsg, "^.*Word [^ ]* of ", "", "")
    let words = substitute(words, ";.*", "", "")
    return words
endfunc

但它将信息打印到状态栏，所以我认为它不适合您的用例。但速度非常快！

答案 5 :(得分：2)

以下是对Abslom Daak的回答的改进，该回答也适用于视觉模式。

function! WordCount()
  let s:old_status = v:statusmsg
  let position = getpos(".")
  exe ":silent normal g\<c-g>"
  let stat = v:statusmsg
  let s:word_count = 0
  if stat != '--No lines in buffer--'
    if stat =~ "^Selected"
      let s:word_count = str2nr(split(v:statusmsg)[5])
    else
      let s:word_count = str2nr(split(v:statusmsg)[11])
    end
    let v:statusmsg = s:old_status
  end
  call setpos('.', position)
  return s:word_count 
endfunction

像以前一样包含在状态行中。这是一个右对齐状态行：

set statusline=%=%{WordCount()}\ words\

答案 6 :(得分：2)

我使用了稍微不同的方法。而不是确保单词计数功能特别快，我只在光标停止移动时调用它。这些命令将执行此操作：

:au CursorHold * exe "normal g\<c-g>"
:au CursorHoldI * exe "normal g\<c-g>"

也许并不是提问者想要的，但比这里的一些答案简单得多，而且对我的用例来说足够好了（在输入一两句话之后看一下字数统计）。

将updatetime设置为较小的值也有帮助：

set updatetime=300

对于字数没有巨大的开销轮询，因为CursorHold和CursorHoldI仅在光标停止移动时一次，而不是每updatetime毫秒。

答案 7 :(得分：1)

我是Vim脚本的新手，但我可能会建议

function WordCount()
    redir => l:status
    exe "silent normal g\<c-g>"
    redir END
    return str2nr(split(l:status)[11])
endfunction

因为它不会覆盖现有的状态行而更加清洁。

我发布的理由是指出这个函数有一个令人费解的错误：即它会破坏append命令。点击 A 会让你进入插入模式，光标位于行上最后一个字符的右边。但是，启用此自定义状态栏后，它会将您置于最终字符的左侧。

任何人都知道是什么原因造成的？

答案 8 :(得分：1)

因为vim现在原生支持此功能：

:echo wordcount().words

答案 9 :(得分：1)

自vim版本7.4.1042起

自vim版本7.4.1042起，您可以按照以下方式简单地更改statusline：

set statusline+=%{wordcount().words}\ words
set laststatus=2    " enables the statusline.

vim-airline中的字数

vim-airline针对许多文件类型提供了标准的字数统计，截至撰写本文时： asciidoc, help, mail, markdown, org, rst, tex ,text

如果vim-airline中未显示字数，则通常是由于无法识别的文件类型。例如，at least for now不能由vim-airline识别复合文件类型markdown.pandoc来进行字数统计。可以通过如下修改.vimrc来轻松地解决此问题：

let g:airline#extensions#wordcount#filetypes = '\vasciidoc|help|mail|markdown|markdown.pandoc|org|rst|tex|text'
set laststatus=2    " enables vim-airline.

\v语句将覆盖默认的g:airline#extensions#wordcount#filetypes变量。最后一行确保启用vim-airline。

如有疑问，在发出以下命令后将返回打开文件的&filetype：

:echo &filetype

这是一个元示例：

vim-airline word count

答案 10 :(得分：1)

这是对Michael Dunn's version的改进，缓存了字数，因此需要更少的处理。

function! WC()
    if &modified || !exists("b:wordcount") 
            let l:old_status = v:statusmsg  
            execute "silent normal g\<c-g>"
            let b:wordcount = str2nr(split(v:statusmsg)[11])
            let v:statusmsg = l:old_status  
            return b:wordcount
    else
            return b:wordcount
    endif
endfunction

答案 11 :(得分：1)

我的建议：

function! UpdateWordCount()
  let b:word_count = eval(join(map(getline("1", "$"), "len(split(v:val, '\\s\\+'))"), "+"))
endfunction

augroup UpdateWordCount
  au!
  autocmd BufRead,BufNewFile,BufEnter,CursorHold,CursorHoldI,InsertEnter,InsertLeave * call UpdateWordCount()
augroup END

let &statusline='wc:%{get(b:, "word_count", 0)}'

我不确定这与其他一些解决方案的速度相比如何，但它肯定比大多数解决方案简单得多。

答案 12 :(得分：1)

我从写作功能的vim帮助页面中获取了大部分内容。

function! WordCount()
  let lnum = 1
  let n = 0
  while lnum <= line('$')
    let n = n + len(split(getline(lnum)))
    let lnum = lnum + 1
  endwhile
  return n
endfunction

当然，和其他人一样，你需要：

:set statusline=wc:%{WordCount()}

我确信有人可以清理这个以使其更具vimmy（s：n而不仅仅是n？），但我相信基本功能就在那里。

编辑：

再看一遍，我真的很喜欢Mikael Jansson的解决方案。我不喜欢炮轰wc（不便携，也许慢）。如果我们用上面的代码替换他的UpdateWordCount函数（将我的函数重命名为UpdateWordCount），那么我认为我们有更好的解决方案。

答案 13 :(得分：0)

如果其他人从谷歌来到这里，我修改了Abslom Daak的答案，与Airline合作。我将以下内容保存为

~/.vim/bundle/vim-airline/autoload/airline/extensions/pandoc.vim

并添加了

call airline#extensions#pandoc#init(s:ext)

到extensions.vim 

let s:spc = g:airline_symbols.space

function! airline#extensions#pandoc#word_count()
if mode() == "s"
    return 0
else
    let s:old_status = v:statusmsg
    let position = getpos(".")
    let s:word_count = 0
    exe ":silent normal g\<c-g>"
    let stat = v:statusmsg
    let s:word_count = 0
    if stat != '--No lines in buffer--'
        let s:word_count = str2nr(split(v:statusmsg)[11])
        let v:statusmsg = s:old_status
    end
    call setpos('.', position)
    return s:word_count 
end
endfunction

function! airline#extensions#pandoc#apply(...)
if &ft == "pandoc"
    let w:airline_section_x = "%{airline#extensions#pandoc#word_count()} Words"
endif
endfunction

function! airline#extensions#pandoc#init(ext)
call a:ext.add_statusline_func('airline#extensions#pandoc#apply')
endfunction

答案 14 :(得分：0)

Guy Gur-Ari的refinement的变体

  • 仅在启用拼写检查的情况下对单词进行计数，
  • 在可视模式下计算所选单词的数量
  • 在插入和普通模式之外保持静音，并且
  • 希望对系统语言（与英语不同）更加了解
function! StatuslineWordCount()
  if !&l:spell
    return ''
  endif

  if empty(getline(line('$')))
    return ''
  endif
  let mode = mode()
  if !(mode ==# 'v' || mode ==# 'V' || mode ==# "\<c-v>" || mode =~# '[ni]')
    return ''
  endif

  let s:old_status = v:statusmsg
  let position = getpos('.')
  let stat = v:statusmsg
  let s:word_count = 0
  exe ":silent normal g\<c-g>"
  try
    if mode ==# 'v' || mode ==# 'V'
      let s:word_count = split(split(v:statusmsg, ';')[1])[0]
    elseif mode ==# "\<c-v>"
      let s:word_count = split(split(v:statusmsg, ';')[2])[0]
    elseif mode =~# '[ni]'
      let s:word_count = split(split(v:statusmsg, ';')[2])[3]
    end
  " index out of range
  catch /^Vim\%((\a\+)\)\=:E\%(684\|116\)/
    return ''
  endtry
  let v:statusmsg = s:old_status
  call setpos('.', position)

  return "\ \|\ " . s:word_count . 'w'
endfunction

可以通过例如

添加到状态行 
    set statusline+=%.10{StatuslineWordCount()}     " wordcount

答案 15 :(得分：0)

使用Steve Moyer提供的答案中的方法，我能够生成以下解决方案。这是一个相当不优雅的黑客，我害怕，我觉得必须有一个更简洁的解决方案，但它的工作原理，并且比每次更新状态行时简单计算缓冲区中的所有单词要快得多。我还应该注意，这个解决方案是独立于平台的，并不假设系统有'wc'或类似的东西。

我的解决方案不会定期更新缓冲区，但Mikael Jansson提供的答案将能够提供此功能。到目前为止，我还没有找到一个我的解决方案不同步的实例。但是我只是简单地对此进行了测试，因为准确的实时字数对我的需求并不重要。我用于匹配单词的模式也很简单，适用于简单的文本文档。如果有人对模式或任何其他建议有更好的想法，请随时发布答案或编辑此帖子。

我的解决方案：

"returns the count of how many words are in the entire file excluding the current line 
"updates the buffer variable Global_Word_Count to reflect this
fu! OtherLineWordCount() 
    let data = []
    "get lines above and below current line unless current line is first or last
    if line(".") > 1
        let data = getline(1, line(".")-1)
    endif   
    if line(".") < line("$")
        let data = data + getline(line(".")+1, "$") 
    endif   
    let count_words = 0
    let pattern = "\\<\\(\\w\\|-\\|'\\)\\+\\>"
    for str in data
        let count_words = count_words + NumPatternsInString(str, pattern)
    endfor  
    let b:Global_Word_Count = count_words
    return count_words
endf    

"returns the word count for the current line
"updates the buffer variable Current_Line_Number 
"updates the buffer variable Current_Line_Word_Count 
fu! CurrentLineWordCount()
    if b:Current_Line_Number != line(".") "if the line number has changed then add old count
        let b:Global_Word_Count = b:Global_Word_Count + b:Current_Line_Word_Count
    endif   
    "calculate number of words on current line
    let line = getline(".")
    let pattern = "\\<\\(\\w\\|-\\|'\\)\\+\\>"
    let count_words = NumPatternsInString(line, pattern)
    let b:Current_Line_Word_Count = count_words "update buffer variable with current line count
    if b:Current_Line_Number != line(".") "if the line number has changed then subtract current line count
        let b:Global_Word_Count = b:Global_Word_Count - b:Current_Line_Word_Count
    endif   
    let b:Current_Line_Number = line(".") "update buffer variable with current line number
    return count_words
endf    

"returns the word count for the entire file using variables defined in other procedures
"this is the function that is called repeatedly and controls the other word
"count functions.
fu! WordCount()
    if exists("b:Global_Word_Count") == 0 
        let b:Global_Word_Count = 0
        let b:Current_Line_Word_Count = 0
        let b:Current_Line_Number = line(".")
        call OtherLineWordCount()
    endif   
    call CurrentLineWordCount()
    return b:Global_Word_Count + b:Current_Line_Word_Count
endf

"returns the number of patterns found in a string 
fu! NumPatternsInString(str, pat)
    let i = 0
    let num = -1
    while i != -1
        let num = num + 1
        let i = matchend(a:str, a:pat, i)
    endwhile
    return num
endf

然后通过以下方式将其添加到状态行：

:set statusline=wc:%{WordCount()}

我希望这可以帮助任何在Vim中寻找实时字数的人。虽然一个并不总是准确的。或者当然g ctrl-g会为你提供Vim的字数！

答案 16 :(得分：0)

以 https://stackoverflow.com/a/60310471/11001018 为基础，我的建议是：

"new in vim 7.4.1042
let g:word_count=wordcount().words
function WordCount()
    if has_key(wordcount(),'visual_words')
        let g:word_count=wordcount().visual_words."/".wordcount().words
    else
        let g:word_count=wordcount().cursor_words."/".wordcount().words
    endif
    return g:word_count
endfunction

然后：

set statusline+=\ w:%{WordCount()},
相关问题
最新问题