Question

我正在尝试为大学课程建立知识库。具体来说，现在我正在尝试制作一个累加器，该累加器将学习一门课程，并提供所有必须首先学习的所有类的列表，例如，课程的先决条件，这些先决条件的先决条件，等等... Based on this chart。

以下是谓词的示例：

prereq(cst250, cst126).
prereq(cst223, cst126).
prereq(cst126, cst116).
prereq(cst105, cst102).
prereq(cst250, cst130).
prereq(cst131, cst130).
prereq(cst130, cst162).
prereq(anth452, wri122).
prereq(hist452, wri122).

这是我对蓄电池的尝试：

prereq_chain(Course, PrereqChain):-
    %Get the list of prereqs for Course
    findall(Prereq, prereq(Course, Prereq), Prereqs),

    %Recursive call to all prereqs in X
    forall(member(X, Prereqs),
           (prereq_chain(X, Y),    
            %Combine current layer prereqs with deeper
            append(Prereqs, Y, Z))),

    %Return PrereqChain
    PrereqChain = Z.

查询的期望输出为：

?- prereq_chain(cst250, PrereqList).
PrereqList = [cst116, cst126, cst162, cst130]

相反，我得到的答案为true，并警告Z为单例。

我看过other posts时也曾问过类似的问题，但它们都只有一条后向遍历通道，而我的解决方案需要多个通道。

谢谢您的指导。

Answer 1

使用forall/2的问题是它无法建立绑定。看这个人为的例子：

?- forall(member(X, [1,2,3]), append(['hi'], X, R)).
true.

如果forall/2为X或R建立了绑定，它将出现在结果中；相反，我们仅获得true，因为它成功了。因此，您需要使用一种结构，该结构不仅会运行一些计算，还会运行会产生值的东西。在这种情况下，您想要的是maplist/3，它需要一个目标和一个参数列表，并建立一个更大的目标，从而为您提供结果。放入以下解决方案后，您将可以在控制台中看到效果。

?- maplist(prereq_chain, [cst126, cst130], X).
X = [[cst116], [cst162]].

因此，它获得了列表中两个类的先决条件列表，但又给了我们一个列表列表。这是append/2派上用场的地方，因为它实际上使列表列表变平：

?- append([[cst116], [cst162]], X).
X = [cst116, cst162].

这是我想出的解决方案：

prereq_chain(Class, Prereqs) :-
    findall(Prereq, prereq(Class, Prereq), TopPrereqs),
    maplist(prereq_chain, TopPrereqs, MorePrereqs),
    append([TopPrereqs|MorePrereqs], Prereqs).

Prolog递归累加器

1 个答案: