Question

我正在尝试创建一个批处理文件以通过网络复制该文件。

首先，我正在使用NET命令映射驱动器，而不是使用xcopy复制文件。

后续批处理文件可以正常工作

    net use T: \\192.168.170.239\D /user:User1 PASSWROD
    set source=T:\backup
    set destination=D:\backup\
    xcopy %source% %destination% /y
    net use T: /delete 
    TIMEOUT 5

我想替换静态IP '192.168.170.239'并按以下方式设置任何IP数组，并循环替换netuse命令。

@echo off 
set obj[0]=192.168.170.239
set obj[1]=192.168.170.240
set obj[2]=192.168.170.241
set obj[3]=192.168.170.242

我已经整理了以下内容，但没有用

 @echo off
set len=2
set obj[0]=192.168.170.239
set obj[1]=192.168.170.240


set i=0
:loop
if %i% equ %len% goto :eof
for /f "usebackq delims== tokens=2" %%j in (`set obj[%i%]`) do (

net use T: \\%%j\D /user:User1 Password
TIMEOUT 10
set source=T:\Autobackup
set destination=D:\Autobackup\
xcopy %source% %destination% /y
net use T: /delete 
TIMEOUT 10

)
set /a i=%i%+1
goto loop

它适用于第二个IP，但不适用于第一个IP。

Answer 1

您应该真正看一下这样的结构：

@Echo Off

Rem Undefine any existing variables beginning with obj[
For /F "Delims==" %%A In ('Set obj[ 2^>Nul') Do Set "%%A=" 

Rem Define your IP list
Set "obj[0]=192.168.170.239"
Set "obj[1]=192.168.170.240"
Set "obj[2]=192.168.170.241"
Set "obj[3]=192.168.170.242"

Rem Define your Map Source and Destination
Set "map=T:"
Set "source=%map%\Autobackup"
Set "destination=D:\Autobackup\"

Rem Loop through the IP list
For /F "Tokens=1* Delims==" %%A In ('Set obj[ 2^>Nul') Do (

    Rem Make sure that %map% is not currently mapped
    Net Use %map% /Delete 2>Nul

    Rem Map the share
    Net Use %map% \\%%B\D /User:User1 Password

    Rem Perform the required operation
    XCopy "%source%" "%destination%" /Y

    Rem Delete the mapped share
    Net Use %map% /Delete 
)

Answer 2

Compo的回答很好。下面是构造循环的另一种方法。它不使用变量的“数组”。我发现这更易于编辑和理解。

SET IPLIST=^
192.168.170.239 ^
192.168.170.240 ^
192.168.170.241 ^
192.168.170.242

FOR %%a IN (%IPLIST%) DO (
    ECHO %%a
)

用批处理文件中的数组替换字符串变量进行循环

2 个答案: