Question

非常简单的问题，还没有解决方案：

C:\> Set var=^%test^%
C:\> Echo %var%
%test%

C:\> Echo %var:^%=-%
%test%

C:\> Why is this not producing -test-?

我尝试加倍并取出胡萝卜（^）但收效甚微。任何建议（或解决方案）赞赏。

莫纳

Answer 1

使用SET搜索和替换替换%的唯一方法是使用延迟扩展。以一种允许你使用正常扩展的方式逃避%是不可能的。

%的规则在批处理与命令提示符之间有所不同。

在批处理脚本中，%通过加倍来转义：

@echo off
setlocal enableDelayedExpansion
set "var=%%test%%"
set var
set "var=!var:%%=-!"
set var

- 输出 -

var=%test%
var=-test-

在命令提示符下，实际上无法逃脱%。如果括在引号内的文本不等于变量名，则百分比保留在原位。此外，未配对的百分比也留在原地。以下代码假定变量test不存在：

C:\test>cmd /v:on
Microsoft Windows [Version 6.1.7601]
Copyright (c) 2009 Microsoft Corporation.  All rights reserved.

C:\test>set "var=%test%"

C:\test>set var
var=%test%

C:\test>set "var=!var:%=-!"

C:\test>set var
var=-test-

C:\test>

如果确实存在变量test，那么您可以使用以下内容设置初始var值：

c:\test>set "var=%^test%"
var=%test%

插入符号“逃脱”下一个字符，因此它被消耗掉，保留正确的值。它可以放在百分比内的任何位置。但代码假定变量^test不存在。如果确实如此，那么它只会扩展该值，如下所示：

C:\test>set "^test=Hello world"

C:\test>set ^^
^test=Hello world

C:\test>set "var=%^test%"

C:\test>set var
var=Hello world

C:\test>

Answer 2

@echo off&setlocal enabledelayedexpansion
Set var=%%test%%
set a=var:%%=
echo var is %var%
echo var%%= is !%a%!

这应该有效... %% not ^％在批处理文件中转义％。在批处理文件中，^％实际上是在％之后转义字符，在本例中是换行符。

替换变量中的“％”

2 个答案: