Question

考虑这两种略有不同的计算第五根的方法：

(define (fifth-root-right x)
  (fixed-point-of-transform (lambda (y) (/ x (expt y 4)))
                            (repeated average-damp 2)
                            1.0))

(define (fifth-root-wrong x)
  (fixed-point (repeated 
                (average-damp (lambda (y) (/ x (expt y 4)))) 
                2)
               1.0))

两者都试图通过平均阻尼搜索固定点来计算第五根，因为x的第五个根是地图的固定点y - >。 X /（Y ^ 4）。我已经定义了

(define (average-damp f)
  (lambda (x) (average x (f x))))
(define tolerance 0.00001)
(define (fixed-point f first-guess)
  (define (close-enough? v1 v2)
    (< (abs (- v1 v2)) tolerance))
  (define (try guess)
    (let ((next (f guess)))
      (if (close-enough? guess next)
          next
          (try next))))
  (try first-guess))
(define (fixed-point-of-transform g transform guess)
  (fixed-point (transform g) guess))
(define (repeated f n)
  (if (= n 1) 
      f
      (compose f (repeated f (- n 1)))))
(define (compose f g) (lambda (x) (f (g x))))

尝试这两种方法，我们得到

> (fifth-root-right 32)
2.000001512995761
> (fifth-root-wrong 32)
2.8804315666156364

为什么第二种方法无法正确计算第五根？更奇怪的是，如果我们在第四或第三根上尝试这种错误的方法，它可以正常工作：

(define (fourth-root x)
  (fixed-point (repeated 
                (average-damp (lambda (y) (/ x (expt y 3)))) 
                2)
               1.0))

(define (cube-root x)
  (fixed-point (repeated 
                (average-damp (lambda (y) (/ x (expt y 2)))) 
                2)
               1.0))


> (fourth-root 16)
1.982985155172348
> (cube-root 8)
2.0000009087630515

作为参考，此代码尝试解决计算机程序的结构和解释中的Exercise 1.45。既然我有正确的方法，我的代码就可以了，但是我不明白为什么我的错误方法是错误的。

Answer 1

本质区别在于重复两次的功能。在正确的一个中，average-damp被施加两次，具有更多阻尼的净效果; ((repeated average-damp 2) f)在数学上减少到(lambda (x) (+ (* 0.75 x) (* 0.25 (f x))))（如果我的语法关闭，道歉，我的口齿非常非常生疏）。这使得算法不易受到变换的大幅波动的影响。

然而，第二个应用(average-damp (lambda (y) (/ x (expt y 2))))两次 - 也就是说，它会阻止转换一次，然后重复生成的函数。 average-damp的一个应用就足以使序列保持发散但不足以实际使其收敛。它实际上会收敛到一个振荡状态，在1.672645084943273和2.8804350135298153之间来回反弹。但是，阻尼变换在每一步都应用两次，因此fixed-point只能看到序列中的每个其他元素 - 即使序列整体无法收敛，该子序列也会收敛到后者。

为什么这些略有不同的寻找根的方法产生不同的结果？

1 个答案: