Question

当http代码不成功并且希望不创建文件时，我需要从getSrc返回的值是什么（通过 sinkFile ）
如果我只是返回 getResponseBody res ，则http错误本身会保存到文件中。

downloadURL :: String -> FilePath -> IO ()
downloadURL url location = do
  request <- parseRequest url
  runResourceT
         $ runConduit$  httpSource request getSrc
         .| sinkFile location
   where
     getSrc res = do
         let success = statusIsSuccessful . getResponseStatus $ res
         if success then
            getResponseBody res
         else
            ???

Answer 1

根据我的理解，如果响应成功，您希望将响应主体传输到某个管道，如果响应不成功，则需要备用管道。

我认为最简单的解决方案将涉及＆＃34;选择＆＃34;使用代码中已有if ... then ... else的管道 - 类似

module Main where

import Conduit ( printC
               )
import Data.Conduit ( runConduitRes
                    , (.|)
                    , yield
                    )
import Data.Conduit.Binary ( sinkFile
                           )
import Network.HTTP.Simple ( parseRequest
                           , httpSource
                           , getResponseStatus
                           , getResponseBody
                           )
import Network.HTTP.Types.Status ( statusIsSuccessful
                                 )

main :: IO ()
main = do
  requestText <- init <$> readFile "notes/request.txt"
  downloadURL requestText "notes/sink.txt"

downloadURL :: String -> FilePath -> IO ()
downloadURL url location = do
  request <- parseRequest url
  runConduitRes (httpSource request processResponse)
    where
  processResponse response =
    if statusIsSuccessful (getResponseStatus response)
    then (getResponseBody response) .| sinkFile location 
    else yield "an alternate operation" .| printC

您可以将yield "an alternate operation" .| printC替换为您实际需要的其他管道。

请注意，现在sinkFile location仅在成功案例中执行，因此失败案例不会创建任何文件。

Answer 2

Kartin的解决方案应该可以正常工作。您可以采用的另一种方法是使用sinkFileCautious而不是sinkFile，并在无效的状态代码上抛出运行时异常。实际上，您可以将parseRequest替换为parseUrlThrow以自动获得此行为。

管道http流式传输到文件（sinkFile）避免在http返回错误时创建文件

2 个答案: