Question

我在为IsList实现GADT实例时遇到了麻烦，它表示嵌套数组中的值结构。这是完整的代码：

{-# LANGUAGE DataKinds         #-}
{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE GADTs             #-}
{-# LANGUAGE RankNTypes        #-}
{-# LANGUAGE TypeFamilies      #-}

import GHC.Exts (IsList (..))

data ValType = TInt | TList

data Val (t :: ValType) where
    I :: Int -> Val 'TInt
    L :: [Val a] -> Val 'TList

instance Show (Val t) where
  show (I i) = "I " ++ show i
  show (L a) = show a

instance IsList (Val 'TList) where
    type Item (Val 'TList) = forall a . Val a

    fromList = L
    toList = error "Not implemented!"

我看到了这样的错误：

GADT.hs:20:10: error:
    • Illegal polymorphic type: forall (a :: ValType). Val a
    • In the type instance declaration for ‘Item’
      In the instance declaration for ‘IsList (Val  'TList)’
   |
20 |     type Item (Val 'TList) = forall a . Val a
   |          ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^

我部分理解为什么会出现此错误。但是我想知道是否可以为IsList类型实现Val实例？

Answer 1

IsList似乎不适合这一点，因为项目类型Item l必须由列表类型l确定。但是，可以使用RebindableSyntax：

进一步推送列表重载

{-# LANGUAGE RebindableSyntax, OverloadedLists #-}

fromListN :: _Int -> [Val a] -> Val 'TList
fromListN _ = L

现在[[I 3, I 2]]是fromListN 1 [fromListN 2 [I 3, I 2]]的糖，减少到L [L [I 3, I 2]]。

我们可以使用类似IsList的类型类来保持原始行为，但这会将项目和列表类型分离。

class IsList item l where
  fromListN :: Int -> [item] -> l

instance IsList (Val a) (Val 'TList) where
  fromListN _ = L

instance (item ~ item') => IsList item [item'] where
  fromListN _ = id

Answer 2

您只是存储L ...在其类型中包含Val a列表的事实，从而丢弃信息。如果你保留这些信息

data ValType = TInt | TList ValType

data Val (t :: ValType) where
    I :: Int     -> Val 'TInt
    L :: [Val a] -> Val ('TList a)

然后可以从标准库中实现IsList类型类的实例：

instance IsList (Val ('TList a)) where
    type Item (Val ('TList a)) = Val a

    fromList      = L
    toList (L xs) = xs

-- (For completeness, this example requires the OverloadedLists extension)
example :: String
example = show ([I 1, I 2, I 3] :: Val ('TList TInt))

另请注意，您可以实施toList。由于此toList具有类型Val ('TList a) -> [Val a]，因此无法传递非列表，因此上述实现不是部分的。您可以使用类型漏洞自行验证此类型：toList = _。您还可以验证（尝试）实现（如下所示）将产生类型错误：toList (I x) = undefined。

列表中的每个项目必须具有相同的类型（例如，您不能将混合整数与列表放在一个列表中），但问题的原始代码也是如此。

GADT的'IsList'实例

2 个答案: