Question

在KDB wj函数中：

wj[w;c;t;(q;(f0;c0);(f1;c1))]

我想拥有任意数量的聚合函数。

myList: `A`B`C..... (can be arbitrary)

我想生成一个sum函数列表

mySumFuncs: {(sum;x)} each myList

并以这种方式使用它：

wj[w;c;t;(q,mySumFuncs)]

但它抱怨type错误。有人可以帮忙吗？

Answer 1

最后一个参数格式不正确尝试

wj[w;c;t;enlist[q],mySumFuncs]

这是因为wj的最后一个参数需要格式为（table; agg1; agg2; ...; aggn）。由于表是没有登记的字典列表，因此聚合被修改为字典列表而不是表格是第一个项目的列表。

更容易看到，下面基于http://code.kx.com/q/ref/joins/#wj-wj1-window-join

中的wj示例

q)w:-2 1+\:t.time
q)t:([]sym:3#`ibm;time:10:01:01 10:01:04 10:01:08;price:100 101 105)
q)q:([]sym:9#`ibm;time:10:01:01+til 9;ask:101 103 103 104 104 107 108 107 108;bid:98 99 102 103 103 104 106 106 107)
q)f:`sym`time
q)w:-2 1+\:t.time
q)q)wj[w;f;t;(q;(max;`ask);(min;`bid))]
sym time     price ask bid
--------------------------
ibm 10:01:01 100   103 98
ibm 10:01:04 101   104 99
ibm 10:01:08 105   108 104
q)(q;(max;`ask);(min;`bid))
+`sym`time`ask`bid!(`ibm`ibm`ibm`ibm`ibm`ibm`ibm`ibm`ibm;10:01:01 10:01:02 10..
(max;`ask)
(min;`bid)
q)q,((max;`ask);(min;`bid))
`sym`time`ask`bid!(`ibm;10:01:01;101;98)
`sym`time`ask`bid!(`ibm;10:01:02;103;99)
`sym`time`ask`bid!(`ibm;10:01:03;103;102)
`sym`time`ask`bid!(`ibm;10:01:04;104;103)
`sym`time`ask`bid!(`ibm;10:01:05;104;103)
`sym`time`ask`bid!(`ibm;10:01:06;107;104)
`sym`time`ask`bid!(`ibm;10:01:07;108;106)
`sym`time`ask`bid!(`ibm;10:01:08;107;106)
`sym`time`ask`bid!(`ibm;10:01:09;108;107)
(max;`ask)
(min;`bid)
q)enlist[q],((max;`ask);(min;`bid))
+`sym`time`ask`bid!(`ibm`ibm`ibm`ibm`ibm`ibm`ibm`ibm`ibm;10:01:01 10:01:02 10..
(max;`ask)
(min;`bid)

为wj生成任意函数

1 个答案: