Question

我最近在Google Play应用商店中发现了一款名为Cryptogram的小游戏。有许多类似于这个的应用程序。我们的想法是将数字与颜色相匹配，以使所有方程听起来都是真的。

我能够很快地解决问题1-8和问题10，但事实证明问题9对我来说更难。

问题9

经过一段时间的修补和猜测，我放弃了，并决定编制一个解决方案。我使用Prolog / Datalog作为一些小任务作为本科生以及一些Project Euler问题。以前我见过15 line Sudoku solver使用Prolog的Constraint Logic Programming over Finite Domains（clpfd）库，我决定自己试一试。我使用SWI-Prolog。

:- use_module(library(clpfd)).
problem(Colors) :-
    Colors = [Pink, Cyan, Yellow, Green, Purple, Red, Brown, White, Lime],
    Colors ins 0..9,
    all_distinct(Colors),
    % The leading digit of a number can't be 0
    Pink #\= 0,
    Red #\= 0,
    White #\= 0,
    Green #\= 0,
    Lime #\= 0,
    Cyan #\= 0,
    % I originally tried to write a predicate generalizing numbers and a list of digits
    % but got in way over my head with CLPFD.
    Number1_1 #= (Pink * 1000) + (Cyan * 100) + (Pink * 10) + Yellow,
    Number1_2 #= (Green * 10) + Purple,
    Number1_3 #= (Cyan * 100) + (Red * 10) + Purple,
    Number2_1 #= (Red * 1000) + (Brown * 100) + (White * 10) + Red,
    Number2_2 #= (Lime * 10) + Yellow,
    Number2_3 #= (Red * 1000) + (Lime * 100) + (Purple * 10) + Pink,
    Number3_1 #= (White * 1000) + (Purple * 100) + (Cyan * 10) + White,
    Number3_2 #= (Green * 1000) + (Cyan * 100) + (Yellow * 10) + Purple,
    Number3_3 #= (Cyan * 1000) + (Red * 100) + (Yellow * 10) + Red,
    % I'm not 100% sure whether to use floored or truncated division here.
    % I thought the difference would be a float vs integer output,
    % but that doesn't make sense with finite domains.
    Number1_1 // Number1_2 #= Number1_3,
    Number1_1 rem Number1_2 #= 0,
    Number2_3 #= Number2_1 + Number2_2,
    Number3_3 #= Number3_1 - Number3_2,
    Number3_1 #= Number1_1 - Number2_1,
    Number3_2 #= Number1_2 * Number2_2,
    Number3_3 #= Number1_3 + Number2_3.

当我在SWI-Prolog中运行此查询时的输出让我觉得我误解了CLPFD中的一个大概念：

?- problem([Pink, Cyan, Yellow, Green, Purple, Red, Brown, White, Lime]).
Pink in 3..9,
_7756#=Pink+10*Purple+1000*Red+100*Lime,
_7810#=1010*Pink+100*Cyan+Yellow,
all_distinct([Pink, Cyan, Yellow, Green, Purple, Red, Brown, White|...]),
Cyan in 1..7,
_7946#=1000*Cyan+10*Yellow+101*Red,
_7994#=100*Cyan+10*Yellow+1000*Green+Purple,
_8048#=10*Cyan+100*Purple+1001*White,
_8096#=100*Cyan+Purple+10*Red,
Yellow in 0..9,
_8162#=Yellow+10*Lime,
Green in 1..7,
_8216#=10*Green+Purple,
Purple in 0..9,
Red in 1..7,
_8294#=1001*Red+100*Brown+10*White,
Brown in 0..9,
White in 2..8,
Lime in 1..9,
_7756 in 1103..7568,
_8096+_7756#=_7946,
_8294+_8162#=_7756,
_8096 in 110..779,
_7810//_8216#=_8096,
_7810 in 3334..9799,
_8048+_8294#=_7810,
_7810 rem _8216#=0,
_8048 in 2313..8778,
_7946+_7994#=_8048,
_7946 in 1213..7678,
_7994 in 1100..7565,
_8216*_8162#=_7994,
_8216 in 12..79,
_8162 in 14..99,
_8294 in 1021..7486.

我希望颜色列表中的每种颜色都绑定到0..9范围内的单个不同整数，但这不是发生的事情。你能帮我找到解决这个问题的方法吗？

修改

所以我选择了一种任意颜色并开始在约束条件应该有效的范围内分配数字。我用Cyan绑定到1运行此查询。

?- problem([Pink, 1, Yellow, Green, Purple, Red, Brown, White, Lime]).
false.

哪个没有意义。之前的＆＃34;输出＆＃34;说＆＃34; Cyan在1..7＆＃34;，我认为这意味着该范围内的任何值都是有效的。但是，如果我为Cyan选择另一个任意值：

?- problem([Pink, 2, Yellow, Green, Purple, Red, Brown, White, Lime]).
Pink = 7,
Yellow = 6,
Green = 3,
Purple = 4,
Red = 1,
Brown = 8,
White = 5,
Lime = 9.

我得到了我正在寻找的答案。虽然密码已经解决了，但我仍然不明白为什么Prolog的CLPFD库没有完全独立地找到它。

编辑2

我用你的建议来清理代码。我还重新引入了将数字与数字联系起来的谓词。这段代码块完美无缺。

:- use_module(library(clpfd)).

digit_number(0, [], 1).

digit_number(Number, [Digit|Tail], DigitPlace) :-
    digit_number(NextNumber, Tail, NextDigitPlace),
    DigitPlace #= NextDigitPlace * 10,
    PlaceNumber #= Digit * (NextDigitPlace),
    Number #= PlaceNumber + NextNumber.

digit_number(Number, ColorList) :-
    digit_number(Number, ColorList, _).

problem(Colors) :-
    Colors = [Pink, Cyan, Yellow, Green, Purple, Red, Brown, White, Lime],
    Colors ins 0..9,
    all_distinct(Colors),
    digit_number(Number1_1, [Pink, Cyan, Pink, Yellow]),
    digit_number(Number1_2, [Green, Purple]),
    digit_number(Number1_3, [Cyan, Red, Purple]),
    digit_number(Number2_1, [Red, Brown, White, Red]),
    digit_number(Number2_2, [Lime, Yellow]),
    digit_number(Number2_3, [Red, Lime, Purple, Pink]),
    digit_number(Number3_1, [White, Purple, Cyan, White]),
    digit_number(Number3_2, [Green, Cyan, Yellow, Purple]),
    digit_number(Number3_3, [Cyan, Red, Yellow, Red]),
    Number1_1 // Number1_2 #= Number1_3,
    Number1_1 rem Number1_2 #= 0,
    Number2_1 + Number2_2 #= Number2_3,
    Number3_1 - Number3_2 #= Number3_3,
    Number1_1 - Number2_1 #= Number3_1,
    Number1_2 * Number2_2 #= Number3_2,
    Number1_3 + Number2_3 #= Number3_3,
    label(Colors).

Answer 1

您的代码有效，只需添加标签（C）：

?- problem(C), label(C).
C = [7, 2, 6, 3, 4, 1, 8, 5, 9] .

Answer 2

另一个答案向您展示了获得所需结果的一种方法，但我想回答您的一些问题。

我仍然不明白为什么Prolog的CLPFD库没有完全独立地找到它。

Prolog是一种或多或少的声明性编程语言，但是（虽然我们喜欢假装，出于宣传的原因），你不能只写下逻辑上等同于你的问题的任何东西，并期望它能够正确有效地执行。特别是，不同目标的执行顺序很重要，即使它没有任何逻辑差异。算术尤其如此。考虑：

?- between(1, 99999999, N), N > 99999998.
N = 99999999.  % correct but slooooow

?- N > 99999998, between(1, 99999999, N).
ERROR: >/2: Arguments are not sufficiently instantiated

对CLP（FD）做同样的工作要好得多：

?- N in 1..99999999, N #> 99999998.
N = 99999999.  % correct and fast!

?- N #> 99999998, N in 1..99999999.
N = 99999999.  % also correct, also fast!

CLP（FD）允许您编写更正确，更具声明性且通常比其他解决方案更有效的程序，除非您手动优化它们。

为实现这一目标，与普通Prolog不同，CLP（FD）将约束集合与实际搜索解决方案分开。当您的程序出现并创建约束时，CLP（FD）将进行一些简化，例如在您自己确定Cyan in 1..7的示例中，或者在上面的示例中，它可以立即找到唯一解决方案。但总的来说，这些简化并不能完全解决问题。

这样做的一个原因就是性能：搜索速度很慢。如果知道更多约束，它会更快，因为对已经受约束的变量的新约束只能使搜索空间变小，但永远不会更大！延迟它直到实际需要具体答案才有意义。

出于这个原因，要实际获得具体结果，您需要调用系统地枚举解决方案的标记谓词。在SWI-Prolog中，简单的是indomain/1和label/1;一般的是labeling/2。后者甚至允许您影响搜索空间探索策略，如果您对问题域有一定的了解，这可能很有用。

之前的“输出”表示“1：7中的青色”，我认为这意味着该范围内的任何值都有效。

不完全：这意味着如果有Cyan的有效解决方案，那么它在1到7的范围内。它不能保证所有值都在这个范围是解决方案。例如：

?- X in 1..5, Y in 1..5, X #< Y.
X in 1..4,
X#=<Y+ -1,
Y in 2..5.

3位于1..4范围内，3位于2..5范围内，因此纯粹基于此，我们可能会期望使用X = 3和Y = 3的解决方案。但由于额外的限制，这是不可能的。只有标签实际上会为您提供有保证解决方案的答案，并且只有在您标记查询中的所有变量时才会这样做。

另见这里非常好的答案：https://stackoverflow.com/a/27218564/4391743

编辑：

% I'm not 100% sure whether to use floored or truncated division here.
% I thought the difference would be a float vs integer output,
% but that doesn't make sense with finite domains.
Number1_1 // Number1_2 #= Number1_3,

事实上，分数除法在这里没有意义，但Prolog会告诉你：

?- X in 1..5, Y in 1..5, Z #= X // Y.
X in 1..5,
X//Y#=Z,
Y in 1..5,
Z in 0..5.

?- X in 1..5, Y in 1..5, Z #= X / Y.
ERROR: Domain error: `clpfd_expression' expected, found `_G6388/_G6412'

与Prolog CLPFD的密码拼图

2 个答案: