按月计算，部分月份

Question

我需要的是计算一个月内的可用性（WTF），并将其除以选定月份的月份之日。

公式应为：WTF /每月总天数*每月可用天数=结果

例如：

period: 07-09-2017 - 15-11-2017
WTF: 0.5

应该导致：

September: 0,4000
October:   0,5000
November:  0,2500

我的问题是如何计算期间超过2个月的结果。我无法弄清楚如何计算第一个月和最后一个月之间的月份结果，因此在10月这个月的情况下。

Answer 1

这里有一些代码可以帮助您入门。它以一个字符串输出值，但您可以轻松地将其输出到三个不同的单元格：

Public Function OutputWork(first As Date, last As Date, wtf As Double)
    Dim worked As Object, total As Object
    Dim i As Date
    Dim j As Long
    Dim mnth As String, key As String
    Dim v As Variant

    Set worked = CreateObject("Scripting.Dictionary")
    Set total = CreateObject("Scripting.Dictionary")

    For i = WorksheetFunction.EoMonth(first, -1) + 1 To WorksheetFunction.EoMonth(last, 0)
        mnth = Format(i, "mmmm")
        If Not total.exists(mnth) Then
            total.Add key:=mnth, Item:=1
        Else: total.Item(mnth) = total.Item(mnth) + 1
        End If

        If Not worked.exists(mnth) Then worked.Add key:=mnth, Item:=0
        If i >= first And i <= last Then worked.Item(mnth) = worked.Item(mnth) + 1
    Next i

    ReDim v(LBound(total.keys()) To UBound(total.keys()))
    For j = LBound(v) To UBound(v)
        key = total.keys()(j)
        v(j) = key & ":" & wtf / total.Item(key) * worked.Item(key)
    Next j

    OutputWork = Join(v, ", ")
End Function

使用工作表上的功能如下：

=OutputWork(<start>,<end>,<WTF>)