Question

我有一个xml元素：

<myElement>item1 item2 item3</myElement>

我想使用XSLT将其转换为：

<newElement>item1</newElement>  
<newElement>item2</newElement>
<newElement>item3</newElement>

xslt看起来怎么样？我对如何循环myElement列表或如何使它成为列表或变量更感兴趣。

请告知。

Answer 1

此转化：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>


 <xsl:template match="text()[contains(., ' ')]" name="tokenize">
  <xsl:param name="pText" select="."/>

  <xsl:if test="string-length($pText)">
   <newElement>
    <xsl:value-of select=
     "substring-before(concat($pText,' '),' ')"/>
   </newElement>

   <xsl:call-template name="tokenize">
    <xsl:with-param name="pText" select=
     "substring-after($pText,' ')"/>
   </xsl:call-template>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

应用于提供的XML文档：

<myElement>item1 item2 item3</myElement>

生成想要的正确结果：

<newElement>item1</newElement>
<newElement>item2</newElement>
<newElement>item3</newElement>

Answer 2

在XSLT 2.0中，它更容易：

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="myElement">
   <xsl:for-each select="tokenize(., '\s+')">
     <newElement><xsl:value-of select="."/></newElement>
   </xsl:for-each>
 </xsl:template>

</xsl:stylesheet>

XSLT：将值读取为列表或数组

2 个答案: