Question

我将从XML文件中获取一个值， e.g。

<WORD>Men</WORD>

然后，我想在XSLT 1.0中创建一个数组，例如

<array>
<Item>Men</Item>
<Item>Women</Item>
</array>

如果XML文件中的值与数组中的某个项匹配，则返回true。谁能告诉我怎么办呢？谢谢！

Answer 1

看来你正在寻找exsl：node-set的扩展功能。看看：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:exsl="http://exslt.org/common" extension-element-prefixes="exsl">

  <xsl:param name="InputArray">
    <array>
      <Item>Men</Item>
      <Item>Women</Item>
    </array>
  </xsl:param>

  <xsl:param name="InputItem">
    <WORD>Men</WORD>
  </xsl:param>

  <xsl:template match="/">
    <xsl:choose>
      <xsl:when test="exsl:node-set($InputArray)//Item[text()=exsl:node-set($InputItem)//text()]">
        <xsl:text>Yes</xsl:text>
      </xsl:when>
      <xsl:otherwise>
        <xsl:text>No</xsl:text>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>

Answer 2

<xsl:stylesheet 
  version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:exsl="http://exslt.org/common" 
  xmlns:internal="http://tempuri.org/config"
  exclude-result-prefixes="internal"
  extension-element-prefixes="exsl"
>
  <internal:config>
    <array>
      <Item>Men</Item>
      <Item>Women</Item>
    </array>
  </internal:config>

  <xsl:variable name="config" select="document('')/*/internal:config" />

  <xsl:template match="WORD">
    <xsl:if test="$config/array/Item[. = current()]">
      <xsl:value-of select="concat('The current value ', ., ' was found.')" />
    </xsl:if>
  </xsl:template>

</xsl:stylesheet>

注意：

使用临时命名空间在XSLT程序中存储配置。
使用exclude-result-prefixes来防止将临时名称空间泄露到结果文档中
使用document('')从内部访问内容样式表。

Answer 3

条件$doc//WORD = $table//item在您希望它时为true，如果$ doc和$ table被适当绑定，则为false。

匹配数组中的值（XSLT）

3 个答案: