Question

我在使用一些Common Lisp代码时遇到了麻烦。我有两个函数类似于下面的函数：

(defun recursive-func (func lst num)
  (let ((test
          (some-func func
                     (first lst)
                     (first (rest lst))
                     num))
        (next
          (recursive-func func
                          (rest lst)
                          num)))

    (cond ((null (rest lst)) nil)
          ((null test) next)
          (t (cons test next)))))

(defun some-func (func a b num)
  (if (> a b)
      nil
      (funcall func a b num)))

当列表中只有一个元素我希望recursive-func返回nil，但它没有，并且调用some-func生成评估中止，因为b是{{1} }}。这是执行的痕迹：

nil

我希望有人可以帮助我，谢谢。

Answer 1

首先评估let中的绑定，然后才在cond中执行测试。你只需要改变一下：

(defun recursive-func (func list num)
  (if (null (rest list))
      nil
      (let ((test (some-func func
                             (first list)
                             (first (rest list))
                             num))
            (next (recursive-func func
                                  (rest list)
                                  num)))
        (cond ((null test) next)
              (t (cons test next))))))

请注意，cond也可以写成：

(if test (cons test next) next)

用你的例子：

(recursive-func (lambda (x y z) (+ x y z))
                '(1 2 3 4 5)
                5)
=> (8 10 12 14)

或者，以下是分解任务的方法（在REPL中）：

> (maplist (lambda (list)
             (list
              (first list)
              (second list)))
           '(1 2 3 4 5))
=> ((1 2) (2 3) (3 4) (4 5) (5 NIL))

首选SECOND代替(first (rest ...))。最后一个结果在REPL中绑定到变量*。使用BUTLAST删除最后一个（无用）对：

(butlast *)
=> ((1 2) (2 3) (3 4) (4 5))

然后，对于此列表中的每对情侣，请调用您的函数 - 这里只是+。请注意使用DESTRUCTURING-BIND：

(mapcar (lambda (list)
          (destructuring-bind (a b) list
            (+ a b 5)))
        *)
=> (8 10 12 14)

所以，基本上，你的功能可以写成：

(defun map-pair-funcall (function list number)
  (mapcar (lambda (pair)
            (destructuring-bind (a b) pair
              (funcall function a b number)))
          (butlast (maplist (lambda (list)
                              (list (first list) (second list)))
                            list))))

因此：

(map-pair-funcall #'+ '(1 2 3 4 5) 5)
=> (8 10 12 14)

编辑：

我错过了提供的函数可能返回NIL的情况。将mapcar的表单换成(remove NIL (mapcar ...))以过滤掉该表单。

您可以使用MAPCON在一次迭代中执行所有操作。该函数迭代子列表，并连接结果列表。因此，被调用的函数应返回列表，当您返回NIL时，结果将被丢弃。

让我们定义ensure-list（或使用Alexandria中的那个）：

(defun ensure-list (expr)
  (if (listp expr) expr (list expr)))

该函数将返回的值包装在列表中，除非它已经是一个列表（特别是NIL）。然后，该函数定义如下：

(defun map-pair-funcall (function list number)
  (mapcon (lambda (list)
            (and (second list)
                 (ensure-list (funcall function
                                       (first list)
                                       (second list)
                                       number))))
          list))

你也可以LOOP：

(defun map-pair-funcall (function list number)
  (loop 
    for (a b) on list
    for result = (and b (funcall function a b number))
    when result
      collect result))

内部的Cond无法正常工作

1 个答案: