Question

问题陈述

我有一个动态SQL，我需要存储在一个表中，但之前存储sql我需要用列表列表验证sql 存储在另一个表中。如果不执行查询，是否可以在select？
中找到列的名称

Approach1 只有我能想到的选项是，尝试使用查询的解释计划并读取数据字典表中的元数据。但遗憾的是我无法找到任何包含此类数据的表。如果您知道这些数据，请告诉我。？

Approach2 使用DBMS_SQL.DESCRIBE_COLUMNS包来查找列名，但我相信这将执行整个查询。

Answer 1

您不需要执行查询来获取列名，您只需要解析它;例如举个简单的例子：

set serveroutput on

declare
  l_statement varchar2(4000) := 'select * from employees';
  l_c pls_integer;
  l_col_cnt pls_integer;
  l_desc_t dbms_sql.desc_tab;
begin
  l_c := dbms_sql.open_cursor;
  dbms_sql.parse(c=>l_c, statement=>l_statement, language_flag=>dbms_sql.native);
  dbms_sql.describe_columns(c=>l_c, col_cnt=>l_col_cnt, desc_t=>l_desc_t);

  for i in 1..l_col_cnt loop
    dbms_output.put_line(l_desc_t(i).col_name);
  end loop;

  dbms_sql.close_cursor(l_c);
exception
  when others then
    if (dbms_sql.is_open(l_c)) then
      dbms_sql.close_cursor(l_c);
    end if;
    raise;
end;
/

输出：

EMPLOYEE_ID
FIRST_NAME
LAST_NAME
EMAIL
PHONE_NUMBER
HIRE_DATE
JOB_ID
SALARY
COMMISSION_PCT
MANAGER_ID
DEPARTMENT_ID

PL/SQL procedure successfully completed.

您可以对循环内的列名进行任何验证。

请记住，您只会看到（并验证）列表达式的列名称或别名，这些列名称或别名不一定反映实际检索的数据。有人可以制作一个查询，从任何有权访问的地方提取任何数据，然后给出被认为有效的列/表达式别名。

如果您尝试限制对特定数据的访问，请查看其他机制，如视图，虚拟专用数据库等。

Answer 2

DBMS_SQL.PARSE不会执行SELECT语句，但将执行DDL语句。如果字符串'select * from employees'被'drop table employees'替换，则代码将失败，但表仍将被删除。

如果您只担心检索元数据的性能，那么Alex Poole的答案将会正常运作。

如果您担心运行错误的陈述类型，那么您将要对Alex Poole的答案进行一些调整。

很难判断一个陈述是SELECT而不是其他东西。检查字符串以select开头的简单条件将在99％的时间内起作用，但从99％到100％是一项大量的工作。简单的正则表达式无法跟上所有不同的关键字，注释，替代引用格式，空格等。

/*comment in front -- */ select * from dual
    select * from dual
with asdf as (select * from dual) select * from asdf;
((((((select * from dual))))));

如果您需要100％的准确度，我建议您使用我的开源PLSQL_LEXER。安装完成后，您可以可靠地测试命令类型，如下所示：

select
    statement_classifier.get_command_name('  /*comment*/ ((select * from dual))') test1,
    statement_classifier.get_command_name('alter table asdf move compress') test2
from dual;

TEST1    TEST2
-----    -----
SELECT   ALTER TABLE

如何在不执行整个查询的情况下查找动态查询中使用的列

2 个答案: