Question

我正在为F5负载均衡器制作Nagios的Perl插件。我必须将池名称转换为与SNMP的OID匹配的十进制格式。

my ( $PoolName )         = $ARGV[1];
my ( $rootOIDPoolStatus ) = '1.3.6.1.4.1.3375.2.2.5.5.2.1.2';

例如，$PoolName是"/Common/Atlassian"和我需要将其转换为/.C.o.m.m.o.n./.A.t.l.a.s.s.i.a.n 然后到47.67.111.109.109.111.110.47.65.116.108.97.115.115.105.97.110

一旦转换它们就会被拉入一个变量

my ( $PoolStatus ) = "$rootOIDPoolStatus.$OIDPoolName"

我一直在为Nagios设计其他人的Perl插件，这是其他人正在做的事情，但无论我做什么样的组合，我都无法使其工作。他们的$name将是我的$PoolName

sub to_oid($) {
    my $oid;
    my ($name) = $_[0];
    return "" if ( ! $name );
    $oid = ( length $name ) . '.' . ( join '.', ( map { unpack 'C', $ } ( split '',$name ) ) );
    return $oid;
}

有人可以帮我构建或理解Perl逻辑，以便将$PoolName转换为OID所需的十进制格式吗？

Answer 1

my $poolStatus = join '.', $rootOIDPoolStatus, map ord, split //, $poolName;

不确定代码中的length（）是什么，在示例中没有显示类似的内容。

Answer 2

您似乎使用字符串作为SNMP表的索引。表的索引可以被认为是该表的行号或行id 。通常，表的索引只是从1开始的数字，并且随着表的每一行而增加。这样的数字按原样编码在OID中，即如果表有3列和2行，它们将具有这些OID：

$base.1         # table
$base.1.1       # table entry
$base.1.1.1.1   # col1, row1
$base.1.1.1.2   # col1, row2
$base.1.1.2.1   # col2, row1
$base.1.1.2.2   # col2, row2
$base.1.1.3.1   # col3, row1
$base.1.1.3.2   # col3, row2
            ^---index

有时索引是IP地址，IP：端口的组合，或两个IP地址的组合，尤其是对于IP相关表。作为索引的IP地址如下所示：

$base.1                 # table
$base.1.1               # table entry
$base.1.1.1.1.0.0.127   # col1, row "127.0.0.1"
$base.1.1.1.0.0.0.0     # col1, row "0.0.0.0"
$base.1.1.2.1.0.0.127   # col2, row "127.0.0.1"
$base.1.1.2.0.0.0.0     # col2, row "0.0.0.0"
$base.1.1.3.1.0.0.127   # col3, row "127.0.0.1"
$base.1.1.3.0.0.0.0     # col3, row "0.0.0.0"
            ^^^^^^^---- index

如您所见，索引的长度取决于其数据类型（有专门的IPV4数据类型）。

有时索引是字符串（如您的情况）。当使用字符串时，它必须以某种方式编码以构成＆＃34;行号＆＃34;对于表。作为索引的字符串按字符顺序编码，并以其长度开头，即：

$base.1                     # table
$base.1.1                   # table entry
$base.1.1.1.2.65.66         # col1, row "AB"
$base.1.1.1.3.120.121.122   # col1, row "xyz"
$base.1.1.2.2.65.66         # col2, row "AB"
$base.1.1.2.3.120.121.122   # col2, row "xyz"
$base.1.1.3.2.65.66         # col3, row "AB"
$base.1.1.3.3.120.121.122   # col3, row "xyz"
            ^^^^^^^^^^^^^---- index

所以＆＃34; AB＆＃34;成为＆＃34; 2.65.66＆＃34;因为length('AB')==2和ord('A')==65，ord('B')==66。同样地＆＃34; xyz＆＃34;成为＆＃34; 3.120.121.122＆＃34;。

您的功能to_oid正是如此，尽管我将其简化如下：

#!/usr/bin/env perl

use strict;
use warnings;

sub to_oid
{
    my $string = shift;
    return sprintf('%d.%s', length($string), join('.', unpack('C*', $string)));
}

my $rootOIDPoolStatus = '1.3.6.1.4.1.3375.2.2.5.5.2.1.2';
my $PoolName = '/Common/Atlassian';

my $poolname_oid = to_oid($PoolName);
my $complete_oid = "$rootOIDPoolStatus.$poolname_oid";

print $complete_oid, "\n";

输出：

1.3.6.1.4.1.3375.2.2.5.5.2.1.2.17.47.67.111.109.109.111.110.47.65.116.108.97.115.115.105.97.110
|<------- rootOID ----------->|<------------ poolname_oid ----...--->|

Answer 3

my $PoolStatus = join('.', $rootOIDPoolStatus, unpack('C*', $PoolName));

或

my $PoolStatus = sprintf("%s.%vd", $rootOIDPoolStatus, $PoolName);

Perl ASCII变量为Decimal，带“。”在每封信

3 个答案:

输出：