Question

假设我有两个文本文件（.txt），我有一个包含一个TMemo组件的表单。将两个文本文件快速加载到同一个备忘录中的最佳方法是什么？

Answer 1

使用TStringList加载每个文件，然后使用AddStrings方法将内容传输到备忘录。

var
  Tmp: TStringList;
...
Memo1.Lines.BeginUpdate;
try
  Memo1.Lines.Clear;
  Tmp := TStringList.Create;
  try
    Tmp.LoadFromFile(FileName1);
    Memo1.Lines.AddStrings(Tmp);

    Tmp.LoadFromFile(FileName2);
    Memo1.Lines.AddStrings(Tmp);
  finally
    Tmp.Free;
  end;
finally
  Memo1.Lines.EndUpdate;
end;

事实上，这可以很容易地推广到这样一个可能有用的方法：

procedure AppendMultipleTextFiles(Dest: TStrings; const FileNames: array of string);
var
  FileName: string;
  Tmp: TStringList;
begin
  Dest.BeginUpdate;
  try
    Tmp := TStringList.Create;
    try
      for FileName in FileNames do
      begin
        Tmp.LoadFromFile(FileName);
        Dest.AddStrings(Tmp);
      end;
    finally
      Tmp.Free;
    end;
  finally
    Dest.EndUpdate;
  end;
end;

然后您可以使用如下方法：

Memo1.Lines.Clear;
AppendMultipleTextFiles(Memo1.Lines, [FileName1, FileName2]);

Answer 2

这样的事情：

sl := TstringList.Create;
try
  sl.LoadFromFile('1.TXT');
  memo1.Lines.Add(sl.Text);

  sl.Clear;
  sl.LoadFromFile('2.TXT');
  memo1.Lines.Add(s2.Text);


finally
  sl.Free
end;

Answer 3

没有任何TStringList：

uses System.IOUtils;

Memo1.Text := TFile.ReadAllText('1.txt') + #13#10 + TFile.ReadAllText('2.txt');

当您将带有换行符的字符串分配给TStrings.Text时，此字符串将自动拆分为多个字符串，可通过以下控制台程序进行验证：

program Project1;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils,
  System.Classes,
  System.IOUtils;

var StringList: TStringList;
    s: string;
begin
  try
    StringList := TStringList.Create;
    StringList.Text := TFile.ReadAllText('1.txt');
    for s in StringList do
      begin
        Writeln(s);
        Writeln('-----');
      end;
    Readln;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

来自docwiki

的更多信息

设置Text时，只要遇到回车符或换行符，就会通过分隔为子字符串来解析该值。（这两者不需要形成对）。

此方法提高了可读性，但消耗大量内存。

在Delphi中将两个文本文件加载到一个TMemo组件中的最佳方法是什么？

3 个答案: