Question

我想要一个TMemo，它总是以字符串＆＃39; SELECT c_name FROM＆＃39;开头。并且我想锁定它以便用户无法在TMemo中删除或替换此字符串，他们必须在此字符串后写入文本。有人可以帮助我吗？我尝试了onChange事件，但问题是用户可以在TMemo的开头点击并在开头编辑它。

我正在使用Delphi 6。

Answer 1

TMemo无法满足您的要求。它只是标准Win32 EDIT控件的一个薄包装器，它不支持这种功能。

您需要使用TRichEdit代替。它支持像您所描述的那样保护文本。添加所需文本后，使用TRichEdit.SelStart和TRichEdit.SelLength属性将其选中，然后将TRichEdit.SelAttributes.Protected属性设置为true。如果用户尝试以任何方式修改受保护的文本，TRichEdit将默认拒绝修改（您可以使用TRichEdit.OnProtectChange事件将AllowChange参数设置为true来覆盖该决定）。例如：

RichEdit1.Text := 'SELECT c_name FROM ';
RichEdit1.SelStart := 0;
RichEdit1.SelLength := 19;
RichEdit1.SelAttributes.Protected := True;

更新：默认情况下，保护文本也会阻止用户复制它。如果您希望用户能够复制受保护的文本，则必须明确启用它。虽然TRichEdit有OnProtectChange事件允许访问受保护的文本，但它不会告诉您为什么文本正在请求访问。但是，基础EN_PROTECTED通知会发生。因此，您可以将TRichEdit子类化为直接拦截EN_PROTECTED，然后仅在用户复制受保护文本时返回0（允许访问）。

interface

uses
  ...;

type
  TMyForm = class(TForm)
    RichEdit1: TRichEdit;
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
    DefRichEditWndProc: TWndMethod;
    procedure RichEditWndProc(var Message: TMessage);
  public
    { Public declarations }
  end;

...

implementation

uses
  Richedit;

procedure TMyForm.FormCreate(Sender: TObject);
begin
  DefRichEditWndProc := RichEdit1.WindowProc;
  RichEdit1.WindowProc := RichEditWndProc;

  RichEdit1.Text := 'SELECT c_name FROM ';
  RichEdit1.SelStart := 0;
  RichEdit1.SelLength := 19;
  RichEdit1.SelAttributes.Protected := True;
end;

procedure TMyForm.RichEditWndProc(var Message: TMessage);
begin
  DefRichEditWndProc(Message);
  if Message.Msg = CN_NOTIFY then
  begin
    if TWMNotify(Message).NMHdr.code = EN_PROTECTED then
    begin
      if PENProtected(Message.lParam).Msg = WM_COPY then
        Message.Result := 0;
    end;
  end;
end;

可替换地：

interface

uses
  ...;

type
  TRichEdit = class(ComCtrls.TRichEdit)
  private
    procedure CNNotify(var Message: TWMNotify); message CN_NOTIFY;
  end;

  TMyForm = class(TForm)
    RichEdit1: TRichEdit;
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

...

implementation

uses
  Richedit;

procedure TMyForm.FormCreate(Sender: TObject);
begin
  RichEdit1.Text := 'SELECT c_name FROM ';
  RichEdit1.SelStart := 0;
  RichEdit1.SelLength := 19;
  RichEdit1.SelAttributes.Protected := True;
end;

procedure TRichEdit.CNNotify(var Message: TWMNotify);
begin
  inherited;
  if Message.NMHdr.code = EN_PROTECTED then
  begin
    if PENProtected(Message.NMHdr).Msg = WM_COPY then
      Message.Result := 0;
  end;
end;

Answer 2

嗯，这是可能的，但我不知道，如果你喜欢这个解决方案。

正如已经说过TMemo并没有实现这种行为。所以你必须编写这种行为。

使用应用程序OnIdle事件和内容的纪念品。在每个空闲消息上验证备忘录内容。如果备忘录内容未以'SELECT c_name FROM '开头，则分配纪念品价值，否则将备忘录内容存储到纪念品。

以下是验证和游标保护的示例

type
  TMainForm = class( TForm )
    Memo1: TMemo;
    ApplicationEvents1: TApplicationEvents; // OnIdle = ApplicationEvents1Idle
    procedure ApplicationEvents1Idle( Sender: TObject; var Done: Boolean );
  private
    FMemo1StartWith: string;
    FMemo1Memento  : string;
    procedure ValidateMemo( AMemo: TMemo; const AStartWith: string; var AMemento: string );
  public
    procedure AfterConstruction; override;

  end;

var
  MainForm: TMainForm;

implementation

{$R *.dfm}

procedure TMainForm.AfterConstruction;
begin
  inherited;
  FMemo1StartWith := 'SELECT c_name FROM ';
end;

procedure TMainForm.ApplicationEvents1Idle( Sender: TObject; var Done: Boolean );
begin
  ValidateMemo( Memo1, FMemo1StartWith, FMemo1Memento );
end;

procedure TMainForm.ValidateMemo( AMemo: TMemo; const AStartWith: string; var AMemento: string );
var
  lCurrentContent: string;
begin
  // protect content

  lCurrentContent := AMemo.Text;
  if Pos( AStartWith, lCurrentContent ) = 1
  then
    AMemento := lCurrentContent
  else if Pos( AStartWith, AMemento ) = 1
  then
    AMemo.Text := AMemento
  else
    AMemo.Text := AStartWith;

  // protect cursor position

  if ( AMemo.SelLength = 0 ) and ( AMemo.SelStart < Length( AStartWith ) )
  then
    AMemo.SelStart := Length( AStartWith );
end;

在TMemo中锁定文本的开头

2 个答案: