Question

我正在浏览“Intermediate Perl”，这很酷。我刚刚完成了关于“Schwartzian变换”的部分，在它沉入之后，我开始想知道为什么变换不使用缓存。在具有多个重复值的列表中，转换会重新计算每个值的值，因此我想为什么不使用哈希来缓存结果。这里有一些代码：

# a place to keep our results
my %cache;

# the transformation we are interested in
sub foo {
  # expensive operations
}

# some data
my @unsorted_list = ....;

# sorting with the help of the cache
my @sorted_list = sort {
  ($cache{$a} //= &foo($a)) <=> ($cache{$b} //= &foo($b))
} @unsorted_list;

我错过了什么吗？为什么书中没有列出Schwartzian变换的缓存版本，一般来说只是更好地传播，因为乍一看我认为缓存版本应该更有效率？

修改：daxim在评论中指出这被称为orcish maneuver。所以我并不疯狂，虽然我不太明白这个名字。

Answer 1

（很多其他评论已经编辑）

如果数组查找比散列查找更有效（即$a->[1]比$cache{$a}更快），则规范形式可能比您的代码更有效，即使有很多重复。

<小时/>

基准测试结果：

这是我的基准代码：

# when does an additional layer of caching improve the performance of 
# the Schwartzian transform?

# methods:
#   1. canonical Schwartzian transform
#   2. cached transform
#   3. canonical with memoized function

# inputs:
#   1. few duplicates (rand)
#   2. many duplicates (int(rand))

# functions:
#   1. fast
#   2. slow

use Benchmark;
use Math::BigInt;
use strict qw(vars subs);
use warnings;
no warnings 'uninitialized';

# fast_foo: a cheap operation,  slow_foo: an expensive operation
sub fast_foo { my $x = shift; exp($x) }
sub slow_foo { my $x = shift; my $y = new Math::BigInt(int(exp($x))); $y->bfac() }

# XXX_memo_foo: put caching optimization inside call to 'foo'
my %fast_memo = ();
sub fast_memo_foo {
  my $x = shift;
  if (exists($fast_memo{$x})) {
    return $fast_memo{$x};
  } else {
    return $fast_memo{$x} = fast_foo($x);
  }
}

my %slow_memo = ();
sub slow_memo_foo {
  my $x = shift;
  if (exists($slow_memo{$x})) {
    return $slow_memo{$x};
  } else {
    return $slow_memo{$x} = slow_foo($x);
  }
}

my @functions = qw(fast_foo slow_foo fast_memo_foo slow_memo_foo);
my @input1 = map { 5 * rand } 1 .. 1000;         # 1000 random floats with few duplicates
my @input2 = map { int } @input1;                # 1000 random ints with many duplicates

sub canonical_ST {
  my $func = shift @_;
  my @sorted = map { $_->[0] }
    sort { $a->[1] <=> $b->[1] }
    map { [$_, $func->($_)] } @_;
  return;
}

sub cached_ST {
  my $func = shift @_;
  my %cache = ();
  my @sorted = sort {
    ($cache{$a} //= $func->($a)) <=> ($cache{$b} //= $func->{$b})
  } @_;
  return;
}

foreach my $input ('few duplicates','many duplicates') {
  my @input = $input eq 'few duplicates' ? @input1 : @input2;
  foreach my $func (@functions) {

    print "\nInput: $input\nFunction: $func\n-----------------\n";
    Benchmark::cmpthese($func =~ /slow/ ? 30 : 1000,
             {
              'Canonical' => sub { canonical_ST($func, @input) },
              'Cached'    => sub { cached_ST($func, @input) }
             });
  }
}

和结果（Strawberry Perl 5.12）：

Input: few duplicates
Function: fast_foo
-----------------
           Rate Canonical    Cached
Canonical 160/s        --      -18%
Cached    196/s       22%        --

Input: few duplicates
Function: slow_foo
-----------------
            Rate Canonical    Cached
Canonical 7.41/s        --       -0%
Cached    7.41/s        0%        --

Input: few duplicates
Function: fast_memo_foo
-----------------
           Rate Canonical    Cached
Canonical 153/s        --      -25%
Cached    204/s       33%        --

Input: few duplicates
Function: slow_memo_foo
-----------------
            Rate    Cached Canonical
Cached    20.2/s        --       -7%
Canonical 21.8/s        8%        --

Input: many duplicates
Function: fast_foo
-----------------
           Rate Canonical    Cached
Canonical 179/s        --      -50%
Cached    359/s      101%        --

Input: many duplicates
Function: slow_foo
-----------------
            Rate Canonical    Cached
Canonical 11.8/s        --      -62%
Cached    31.0/s      161%        --

Input: many duplicates
Function: fast_memo_foo
-----------------
           Rate Canonical    Cached
Canonical 179/s        --      -50%
Cached    360/s      101%        --

Input: many duplicates
Function: slow_memo_foo
-----------------
            Rate Canonical    Cached
Canonical 28.2/s        --       -9%
Cached    31.0/s       10%        --

我对这些结果感到有些震惊 - 规范的Schwartzian变换在最有利的条件下（功能昂贵的函数调用，很少重复或没有记忆）只有一点点优势，并且在其他情况下处于相当大的劣势。 sort函数中的OP缓存方案甚至优于sort之外的memoization。当我做基准测试时，我并没有想到这一点，但我认为OP正在发展。

Answer 2

当你在多个变换中调用foo()时，缓存Schwartzian变换会很有用：

@sorted1 = map { $_->[0] }
           sort { $a->[1] cmp $b->[1] }
           map  { [$_, foo($_)] }
           @unsorted1;
@sorted2 = map { $_->[0] }
           sort { $a->[1] cmp $b->[1] }
           map  { [$_, foo($_)] }
           @unsorted2;

如果@unsorted1和@unsorted2的值大致相同，那么您将为foo()调用两次相同的值。如果此函数的计算成本很高，您可能希望缓存结果。

最简单的方法是使用Memoize module：

use Memoize;
memoize('foo');

如果您添加这两行，则无需担心自己为foo()设置缓存，Memoize会为您处理。

编辑：我只是注意到你的排序没有做Schwartzian变换。 ST背后的重点是你只为列表的每个成员运行一次昂贵的函数，这就是你做整个map sort map构造的原因。虽然你可能会像你做的那样做一些手写的缓存，但它会是非标准的Perl（从某种意义上说，某人会期望看到ST，然后必须坐在那里找出你的代码是什么这样做很快就会成为维护的噩梦。

但是，是的，如果您的列表具有重复值，则使用缓存（手动滚动或使用Memoize）可能会导致更快的Schwartzian变换。我说“可能”因为可能存在这样的情况：执行哈希查找实际上比调用foo()更昂贵（Memoize文档使用sub foo { my $x = shift; return $x * $x }作为其中一个实例的示例）。

缓存的schwartzian变换

2 个答案:

基准测试结果：