Question

我需要在binder下概括表达式。例如，我在我的目标中有两个表达式：

(fun a b => g a b c)

和

(fun a b => f (g a b c))

我想概括g _ _ c部分：

一种方法是先将它们重写为：

(fun a b => (fun x y =>  g x y c) a b)

和第二个进入：

(fun a b =>
   f (
       (fun x y =>  g x y c) a b
   ))

然后，将(fun x y, g x y c)概括为somefun类型A -> A -> A。这会将我的表达式变为：

(fun a b => somefun a b)

和

(fun a b => f (somefun a b))

这里的困难在于我试图概括的表达式是在活页夹下。我无法找到策略或LTAC表达来操纵它。我怎么能这样做？

Answer 1

这个答案有两个关键：change tactic，用可转换的一个术语取代一个术语，并推广c，这样就不会处理g _ _ c而是fun z => g _ _ z };第二个密钥允许您处理g而不是g应用于其参数。在这里，我使用pose策略来控制应用程序获得β减少的函数：

Axiom A : Type.
Axiom f : A -> A.
Axiom g : A -> A -> A -> A.
Goal forall c, (fun a b => g a b c) = (fun a b => f (g a b c)).
Proof.
  intro c.
  pose (fun z x y => g x y z) as g'.
  change g with (fun x y z => g' z x y).
  (*   (fun a b : A => (fun x y z : A => g' z x y) a b c) =
       (fun a b : A => f ((fun x y z : A => g' z x y) a b c)) *)
  cbv beta.
  (* (fun a b : A => g' c a b) = (fun a b : A => f (g' c a b)) *)
  generalize (g' c); intro somefun; clear g'.
  (* (fun a b : A => somefun a b) = (fun a b : A => f (somefun a b)) *)

以下是使用id（身份函数）阻止cbv beta而非使用pose的备用版本：

Axiom A : Type.
Axiom f : A -> A.
Axiom g : A -> A -> A -> A.
Goal forall c, (fun a b => g a b c) = (fun a b => f (g a b c)).
Proof.
  intro c.
  change g with (fun a' b' c' => (fun z => id (fun x y => g x y z)) c' a' b').
  (*   (fun a b : A =>
        (fun a' b' c' : A => (fun z : A => id (fun x y : A => g x y z)) c' a' b') a b c) =
       (fun a b : A =>
        f
          ((fun a' b' c' : A => (fun z : A => id (fun x y : A => g x y z)) c' a' b') a
             b c)) *)
  cbv beta.
  (* (fun a b : A => id (fun x y : A => g x y c) a b) =
     (fun a b : A => f (id (fun x y : A => g x y c) a b)) *)
  generalize (id (fun x y : A => g x y c)); intro somefun.
  (* (fun a b : A => somefun a b) = (fun a b : A => f (somefun a b)) *)

在绑定器下推广表达式

1 个答案: