Question

我试图在Haskell中创建一个多变量函数，我使用this回答来创建一个基本函数。这是函数的代码：

class SumRes r where 
    sumOf :: Integer -> r

instance SumRes Integer where
    sumOf = id

instance (Integral a, SumRes r) => SumRes (a -> r) where
    sumOf x = sumOf . (x +) . toInteger

但问题是：在没有任何参数的情况下调用函数时，它不起作用。

Couldn't match expected type 'Integer' with actual type 'Integer -> r0'
    Probable cause: 'sumOf' is applied to too few arguments

例如，我希望能够编写sumOf :: Integer并让此函数返回0。

我该怎么做？

Answer 1

最简单的版本仅适用于Integer结果。

简单方法

这可以解决你已经写过的内容，利用0是添加标识的事实。

class SumRes r where
  sumOf' :: Integer -> r

instance SumRes Integer where
  sumOf' = toInteger

instance (Integral b, SumRes r) => SumRes (b -> r) where
  sumOf' a b = sumOf' $! a + toInteger b

sumOf :: SumRes r => r
sumOf = sumOf' 0

两个实例Integer和b -> r本身并不重叠。

更难的方式

要获得更一般的结果类型，您需要一种稍微不同的方法，因为如果Integer被类型变量替换，上面描述的两个实例会混在一起。您可以使用MultiParamTypeClasses和TypeFamilies。

执行此操作

{-# LANGUAGE ScopedTypeVariables, AllowAmbiguousTypes, DataKinds,
      KindSignatures, TypeApplications, MultiParamTypeClasses,
      TypeFamilies, FlexibleInstances #-}

module SumRes2 where

data Nat = Z | S Nat
class SumRes (c :: Nat) r where
  sumOf' :: Integer -> r

type family CountArgs a :: Nat where
  CountArgs (_ -> r) = 'S (CountArgs r)
  CountArgs _ = 'Z

instance Num r => SumRes 'Z r where
  sumOf' = fromInteger

instance (Integral b, SumRes n r) => SumRes ('S n) (b -> r) where
  sumOf' a b = sumOf' @n (a + toInteger b)

sumOf :: forall r n. (SumRes n r, CountArgs r ~ n) => r
sumOf = sumOf' @n 0

唯一的限制是，如果您有一个功能类型的Integral实例，则无法使用sumOf来生成它。但这不应该是一个问题。我为了简洁起见使用了TypeApplications和AllowAmbiguousTypes，但您当然可以使用代理传递或Tagged代替。

Haskell polyvariadic函数没有参数

1 个答案:

简单方法

更难的方式