Question

跟进this question。我有一个矩阵（是的，我这样做），它很大而且很稀疏。

A = [
     [0,   0, 0, 1.2, 0]
     [0,   0, 0, 0,   0]
     [3.5, 0, 0, 0,   0]
     [0    7, 0, 0,   0]
]

我想创建一个向量v，其v[j] = v[j,] * log(v[j,])

中每行的总和为A

我相信有一个像[x * log(x) for x in row] do...这样的迭代器，但我很难找到语法。一个特别的bugaboo是避免使用log(0)，所以在迭代器中可能有一个if语句？

Answer 1

我相信有一个像[x * log（x）for x in row]这样的迭代器吗...但是我很难找到语法。

我们可以创建一个函数来计算x * log(x)而不是创建一个迭代器，只需将一个数组（或数组切片）传递给它，允许promotion处理其余的事情。

而不是像我们之前那样对数组切片执行+ reduce，

forall i in indices {
  rowsums[i] = + reduce(A[i, ..]);
}

我们可以对数组切片上的提升操作执行+ reduce，如下所示：

forall i in indices {
  rowsums[i] = + reduce(logProduct(A[i, ..]));
}

其中logProduct(x)可以包含处理0特殊情况的if语句，如上所述。

将这一切放在一起看起来像这样：

config const n = 10;

proc main() {
  const indices = 1..n;
  const Adom = {indices, indices};
  var A: [Adom] real;

  populate(A);

  var v = rowSums(A);

  writeln('matrix:');
  writeln(A);

  writeln('row sums:');
  writeln(v);
}


/* Populate A, leaving many zeros */
proc populate(A: [?Adom]) {
  forall i in Adom.dim(1) by 2 do // every other row
    forall j in Adom.dim(2) by 3 do // every third column
      A[i, j] = i*j;
}

/* Compute row sums with custom function (logProduct) */
proc rowSums(A: [?Adom] ?t) {
  var v: [Adom.dim(1)] t;

  [i in v.domain] v[i] = + reduce(logProduct(A[i, ..]));

  return v;
}

/* Custom function to handle log(0) case */
proc logProduct(x: real) {
  if x == 0 then return 0;
  return x * log(x);
}

Chapel中Matrix的自定义rowSums

1 个答案: