Question

以下代码编译为64位，但使用Fortran通用接口似乎会混淆32位的gcc属性（需要调用32位STDCALL API）。代码是我试图为Windows构建的f03gl项目的精简版本（我无法创建更小的repro）。

在没有通用接口和直接传递参数的情况下重做代码（显示在底部）会编译和工作。我希望我不必重写所有要解决此问题的电话。

错误是;

callglutbad.o:callglutbad.f90:(.text+0x27): undefined reference to `glutInit'

callglut.f90（32位编译失败）

MODULE GlutModule
  USE ISO_C_BINDING
  IMPLICIT NONE
  PUBLIC glutInit

  INTERFACE glutInit
    MODULE PROCEDURE glutInit_f03
  END INTERFACE glutInit

  INTERFACE

    SUBROUTINE glutInit_gl(pargc, argv) BIND(C,NAME="glutInit")
      IMPORT

#ifdef x86
!GCC$ ATTRIBUTES stdcall :: glutInit
#endif
      INTEGER(C_INT) :: pargc
      TYPE(C_PTR), INTENT(IN) :: argv
    END SUBROUTINE glutInit_gl

  END INTERFACE

  CONTAINS

  SUBROUTINE glutInit_f03()
    INTEGER(C_INT) :: argcp=1
    TYPE(C_PTR), DIMENSION(1), TARGET :: argv=C_NULL_PTR
    CHARACTER(C_CHAR), DIMENSION(1), TARGET :: empty_string=C_NULL_CHAR

    argv(1)=C_LOC(empty_string)
    CALL glutInit_gl(argcp, C_LOC(argv))

  END SUBROUTINE

END MODULE GlutModule

program main
  USE GlutModule

  PRINT *,"Calling glutInit"
  call glutInit()
  PRINT *,"Called glutInit"

end program main

的build.bat

REM 32 bit 
@setlocal
@SET PATH=%PATH%;C:\msys64\mingw32\bin\
gfortran -Dx86 -cpp -c callglut.f90 -o callglut.o
gcc callglut.o -o callglut32.exe ..\x86\lib\freeglut.lib -lgfortran
@endlocal

REM 64 bit 
@setlocal
@SET PATH=%PATH%;C:\msys64\mingw64\bin\
gfortran -cpp -c callglut.f90 -o callglut.o
gcc callglut.o -o callglut64.exe ..\x64\lib\freeglut.lib -lgfortran
@endlocal

泛型接口用于在没有Fortran参数的情况下调用glutInit（参数由代理子例程填充）。

callglut.f90（在两个平台上编译并运行）

MODULE GlutModule
  USE ISO_C_BINDING
  IMPLICIT NONE
  PUBLIC glutInit

  INTERFACE

    SUBROUTINE glutInit(pargc, argv) BIND(C,NAME="glutInit")
      IMPORT

#ifdef x86
!GCC$ ATTRIBUTES stdcall :: glutInit
#endif
      INTEGER(C_INT) :: pargc
      TYPE(C_PTR), INTENT(IN) :: argv
    END SUBROUTINE glutInit
  END INTERFACE

END MODULE GlutModule

program main
  USE GlutModule

  PRINT *,"Calling glutInit"
  call glutInit(0,C_NULL_PTR)
  PRINT *,"Called glutInit"

end program main

我看到编译器错误，属性语句没有应用于通用接口，还是我正在做的事情？我怀疑这个和32位STDCALL名称从glutInit到_glutInit @ 8没有被执行。

我在msys2（GNU Fortran（Rev2，由MSYS2项目建立）7.1.0）下使用gfortran在64位Windows上同时使用32位和64位编译器。

Answer 1

将STDCALL属性应用于仅作为通用名称的标识符没有意义。从编译器的角度来看，通用名称是许多过程的通用标签。虽然各个特定程序可能具有不同的调用约定，但它们的标签却没有。

如果您想告诉编译器特定过程具有某个调用约定，请在相关声明中使用编译器知道特定过程的名称。

!GCC$ ATTRIBUTES stdcall :: glutInit_gl

这个链接器错误在32位Windows gFortran中是一个错误吗？

1 个答案: