Question

我有一个复杂的逻辑表达式，如下所示：

((((!((cond1) || (cond2) || (cond3)) && (cond4))) && (cond5)) <= (((cond6) || (cond7) || (cond8)) || (cond9)))

每一行都有几十个表达式。允许的逻辑符号为||，&&，!和<=。 <=表示潜在客户，如a <= b表示b指向a。

我需要检查这些陈述并检查条件，因为其中一些不再有效。我希望能够将其解析为树，然后检查每个叶子（每个叶子都是条件），删除不需要的叶子并构建完整正确的表达式。

我知道树的每个节点都是由一对第一个括号和关闭它的括号定义的，但我不知道如何识别这些对以及如何识别它们之间的逻辑符号。

!以外的所有符号都在两个表达式之间。

Answer 1

听起来像Parse::RecDescent的情况：

use strict;
use warnings;
use Parse::RecDescent;

my $text = '((((!((cond1) || (cond2) || (cond3)) && (cond4))) && (cond5)) <= (((cond6) || (cond7) || (cond8)) || (cond9)))';

#$::RD_TRACE=1;

my $grammar = q{

startrule: expr

expr: operand operation(s?)
    { $return = @{$item[2]} ? { 'operations' => $item[2], 'lvalue' => $item[1] } : $item[1] }

operation: /\|\||&&|<=/ operand
    { $return = { 'op' => $item[1], 'rvalue' => $item[2] } }

operand: '(' expr ')'
    { $return = $item[2] }

operand: '!' operand
    { $return = { 'op' => '!', 'value' => $item[2] } }

operand: /\w+/

};

my $parser = Parse::RecDescent->new($grammar);
my $result = $parser->startrule($text) or die "Couldn't parse!\n";

use Data::Dumper;
$Data::Dumper::Indent = 1;
$Data::Dumper::Sortkeys = 1;
print Dumper $result;

语法，用英语写成：

整个事情都是表达。表达式是一个操作数，后跟零个或多个二元运算符及其操作数。每个操作数都是带括号的表达式'！'后跟一个操作数或一个单词（例如cond1）。

生成树中的每个节点都采用以下形式之一：

cond1 - 条件
{ 'op' => '!', 'value' => 'node' } - ！应用于另一个节点
{ 'lvalue' => 'node', 'operations' => [ one or more of: { 'op' => 'binop', 'rvalue' => 'node' } ] } - 一系列表示节点binop节点binop节点的一个或多个操作...

我没有将一系列二进制操作（例如((cond1) || (cond2) || (cond3))）分解为二叉树，因为您没有提供有关优先级或关联性的信息。

您的示例输出为：

$VAR1 = {
  'lvalue' => {
    'lvalue' => {
      'lvalue' => {
        'op' => '!',
        'value' => {
          'lvalue' => 'cond1',
          'operations' => [
            {
              'op' => '||',
              'rvalue' => 'cond2'
            },
            {
              'op' => '||',
              'rvalue' => 'cond3'
            }
          ]
        }
      },
      'operations' => [
        {
          'op' => '&&',
          'rvalue' => 'cond4'
        }
      ]
    },
    'operations' => [
      {
        'op' => '&&',
        'rvalue' => 'cond5'
      }
    ]
  },
  'operations' => [
    {
      'op' => '<=',
      'rvalue' => {
        'lvalue' => {
          'lvalue' => 'cond6',
          'operations' => [
            {
              'op' => '||',
              'rvalue' => 'cond7'
            },
            {
              'op' => '||',
              'rvalue' => 'cond8'
            }
          ]
        },
        'operations' => [
          {
            'op' => '||',
            'rvalue' => 'cond9'
          }
        ]
      }
    }
  ]
};

解析逻辑表达式并将其转换为Perl中的树

1 个答案: