Question

<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
  <s:Header xmlns:s="http://schemas.xmlsoap.org/soap/envelope/" />
  <soapenv:Body>
    <swiftResponseResponse xmlns="http://webservice.sbi.com">
      <swiftResponseReturn>15617TS006140|DC768736|13321.49|04-05-2017 15:13:03|SWIFTINR|NA|FAIL-ACCOUNT UNAVAILABLE</swiftResponseReturn>
    </swiftResponseResponse>
  </soapenv:Body>
</soapenv:Envelope>

`

我的xslt代码是`

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xs="http://webservice.sbi.com" exclude-result-prefixes="soapenv xsl  xsd xsi xs ">
  <!--<xsl:output method="xml" indent="yes"/>-->
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <!--<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>-->


  <xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="separator" />
    <xsl:choose>
        <xsl:when test="not(contains($text, $separator))">
            <swiftResponseReturnValue>
                <xsl:value-of select="$text"/>
            </swiftResponseReturnValue>
        </xsl:when>
        <xsl:otherwise>
            <swiftResponseReturnValue>
                <xsl:value-of select="normalize-space(substring-before($text, $separator))"/>
            </swiftResponseReturnValue>
            <xsl:call-template name="tokenize">
                <xsl:with-param name="text" select="substring-after($text, $separator)"/>
                <xsl:with-param name="separator" select="$separator"/>
            </xsl:call-template>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>
  <!--<xsl:template match="soapenv:Envelope/soapenv:Body/xs:swiftResponseResponse/xs:swiftResponseReturn">-->
    <xsl:template match="soapenv:Envelope/soapenv:Body/xs:swiftResponseResponse/xs:swiftResponseReturn">
    <!--<xsl:element name="Root">-->
      <!--<xsl:element name="swiftResponseReturn">
        <xsl:value-of select="xs:swiftResponseResponse/xs:swiftResponseReturn"/>
      </xsl:element>-->
    <xsl:copy>
        <xsl:variable name="tokenize">
            <xsl:call-template name="tokenize">
                <xsl:with-param name="text" select="."/>
                <xsl:with-param name="separator" select="'|'"/>
            </xsl:call-template>
        </xsl:variable>
        <xsl:copy-of select="$tokenize"/>
    </xsl:copy>
    <!--</xsl:element>-->

  </xsl:template>

</xsl:stylesheet>

`

我的操作是`

<swiftResponseReturn xmlns="http://webservice.sbi.com"
                     xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
                     xmlns:xsd="http://www.w3.org/2001/XMLSchema"
                     xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
   <swiftResponseReturnValue xmlns="">15617TS006140</swiftResponseReturnValue>
   <swiftResponseReturnValue xmlns="">DC768736</swiftResponseReturnValue>
   <swiftResponseReturnValue xmlns="">13321.49</swiftResponseReturnValue>
   <swiftResponseReturnValue xmlns="">04-05-2017 15:13:03</swiftResponseReturnValue>
   <swiftResponseReturnValue xmlns="">SWIFTINR</swiftResponseReturnValue>
   <swiftResponseReturnValue xmlns="">NA</swiftResponseReturnValue>
   <swiftResponseReturnValue xmlns="">FAIL-ACCOUNT UNAVAILABLE</swiftResponseReturnValue>
</swiftResponseReturn>

`

和预期的产出是 `

<swiftResponseReturn>
   <swiftResponseReturnValue1>15617TS006140</swiftResponseReturnValue1>
   <swiftResponseReturnValue2>DC768736</swiftResponseReturnValue2>
   <swiftResponseReturnValue3>13321.49</swiftResponseReturnValue3>
   <swiftResponseReturnValue4>04-05-2017 15:13:03</swiftResponseReturnValue4>
   <swiftResponseReturnValue5>SWIFTINR</swiftResponseReturnValue5>
   <swiftResponseReturnValue6>NA</swiftResponseReturnValue6>
   <swiftResponseReturnValue7>FAIL-ACCOUNT UNAVAILABLE</swiftResponseReturnValue7>
</swiftResponseReturn>

` 我使用模板来破坏代码管道分隔符格式。但我不想要名称空间，也希望使用唯一标识符来区分每个输出。

Answer 1

您正在使用xsl:copy复制swiftResponseReturn元素，但这将包含命名空间。您只需要创建一个没有名称空间的新元素名称xswiftResponseReturn。

尝试用此替换当前模板..

<xsl:template match="xs:swiftResponseReturn">
  <swiftResponseReturn>
     <xsl:call-template name="tokenize">
         <xsl:with-param name="text" select="."/>
         <xsl:with-param name="separator" select="'|'"/>
     </xsl:call-template>
  </swiftResponseReturn>
</xsl:template>

请注意，您不需要在模板匹配中真正需要元素的完整路径。

Answer 2

更通用的解决方案：将<xsl:copy>更改为<xsl:element name="{name()}">。

当然，请记住相应地更改结束标记。

修改

您可以在此处获得更改要求的XSLT脚本：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
  xmlns:xsd="http://www.w3.org/2001/XMLSchema"
  xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
  xmlns:xs="http://webservice.sbi.com" exclude-result-prefixes="#all">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="separator" />
    <xsl:choose>
      <xsl:when test="not(contains($text, $separator))">
        <token>
          <xsl:value-of select="$text"/>
        </token>
      </xsl:when>
      <xsl:otherwise>
        <token>
          <xsl:value-of select="normalize-space(substring-before($text, $separator))"/>
        </token>
        <xsl:call-template name="tokenize">
          <xsl:with-param name="text" select="substring-after($text, $separator)"/>
          <xsl:with-param name="separator" select="$separator"/>
        </xsl:call-template>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

  <xsl:template match="soapenv:Envelope/soapenv:Body/xs:swiftResponseResponse/xs:swiftResponseReturn">
    <xsl:element name="{name()}">
      <xsl:variable name="tokens">
        <xsl:call-template name="tokenize">
          <xsl:with-param name="text" select="."/>
          <xsl:with-param name="separator" select="'|'"/>
        </xsl:call-template>
      </xsl:variable>
      <xsl:for-each select="$tokens/token">
        <xsl:element name="swiftResponseReturnValue{position()}">
          <xsl:value-of select="."/>
        </xsl:element>
      </xsl:for-each>
    </xsl:element>
  </xsl:template>

</xsl:stylesheet>

与您的解决方案相比有哪些变化：

tokenize模板返回token元素序列并将其结果保存在tokens变量中。
来自此变量的标记在for-each循环中处理。
在这个循环中创建了一个alement。它的名字是由组成的来自swiftResponseReturnValue（常量文本）和当前标记的位置编号。
此源标记的内容将打印为内容刚刚创建了标签。

脚本开头还有两个额外的更改：

exclude-result-prefixes属性的值已更改为 #all（更简单，更通用的解决方案）。
我还添加了<xsl:strip-space elements="*"/>以删除额外内容输出中的空格和换行符。

从XSLT输出中删除命名空间

2 个答案:

修改