Question

我一直试图在Sphere内部投射360视频，其中有一个翻转法线用于Google Cardboard VR。视频工作正常，只是水平反转，只有当屏幕上有文字时才会注意到。我在其前面加了一个视频屏幕截图和一个UI.Text元素来比较它。

我试图通过projectionMatrix反转相机的视图但是它最终只是在空白处。屏幕截图：

我无法想办法让视频项目成为正确的方法。请帮忙！

Answer 1

翻转球体上的法线是不够的，您还需要反转UV坐标的U部分（即，更改所有值U，使它们为1-U）。设置一个球体，以便外部从右到左正确呈现文本。当您翻转法线时，“右侧”仍然在右侧从外侧...意味着从内侧看时它位于左侧。

您需要自己手动编辑UV坐标或从资产商店中取出预制的倒置球体（IIRC有两个免费提供）。

Answer 2

Here is a shader that displays the content correctly without inverting it, I have tested it with Unity 2018.1.1 as I am currently using it in my project:

Shader "InsideVisible" {
Properties {
    _MainTex ("Base (RGB)", 2D) = "white" {}
}

SubShader {
    Tags { "RenderType"="Opaque" }
    Cull front    // ADDED BY BERNIE, TO FLIP THE SURFACES
    LOD 100

    Pass {  
        CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct appdata_t {
                float4 vertex : POSITION;
                float2 texcoord : TEXCOORD0;
            };

            struct v2f {
                float4 vertex : SV_POSITION;
                half2 texcoord : TEXCOORD0;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;

            v2f vert (appdata_t v) {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                // ADDED BY BERNIE:
                v.texcoord.x = 1 - v.texcoord.x;                
                o.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target {
                fixed4 col = tex2D(_MainTex, i.texcoord);
                return col;
            }
        ENDCG
        }
    }
}

If you need more information about the shader you can view this tutorial.

Unity中VR球体中的倒置视图

2 个答案: