SAS - 为所有变量创建虚拟变量

Question

我有一个数据集，其中包含给定记录的X个分类变量。我想以某种方式将此数据集转换为具有虚拟变量的新数据集，但我希望有一个命令/宏来获取数据集并为数据集中的所有变量创建虚拟变量。

我也不想指定每个变量的名称，因为我可以拥有一个包含50个变量的数据集，因此必须指定每个变量名称太麻烦了。

假设我有一个这样的表，我想要结果表，上面的条件是我想要一个命令或单个宏而不指定每个单独的变量：

Answer 1

您可以使用PROC GLMSELECT生成设计矩阵，这就是您所要求的。

data test;
   input id v1 $ v2 $ v3 $ ;
   datalines;
1 A A A
2 B B B
3 C C C
4 A B C
5 B A A
6 C B A
;

proc glmselect data=test outdesign(fullmodel)=test_design noprint ;
   class v1 -- v3;
   model id = v1 -- v3 /selection=none noint;
run;

您可以使用--指定第一个和最后一个之间的所有变量。请注意，我不必输入v2。所以，如果你知道第一个和最后一个，你可以轻松地得到你想要的东西。

Answer 2

我自己更喜欢GLMMOD。请注意，如果可以的话，CLASS变量通常是更好的方法，但不是所有PROCS都支持。

/*Run model within PROC GLMMOD for it to create design matrix
Include all variables that might be in the model*/
proc glmmod data=sashelp.class outdesign=want outparm=p;
    class sex age;
    model weight=sex age height;
run;

/*Create rename statement automatically
THIS WILL NOT WORK IF YOUR VARIABLE NAMES WILL END UP OVER 32 CHARS*/
data p;
    set p;

    if _n_=1 and effname='Intercept' then
        var='Col1=Intercept';
    else
        var=catt("Col", _colnum_, "=", catx("_", effname, vvaluex(effname)));
run;

proc sql ;
    select var into :rename_list separated by " " from p;
quit;

/*Rename variables*/
proc datasets library=work nodetails nolist;
    modify want;
    rename &rename_list;
    run;
quit;

proc print data=want;
run;

最初来自这里，帖子有几个其他方法的链接。 https://communities.sas.com/t5/SAS-Communities-Library/How-to-create-dummy-variables-Categorical-Variables/ta-p/308484

Answer 3

以下是使用简单的三个观察数据集和@Reeza发布的PROC GLMMOD方法的修改版本的工作示例

首先，让我们制作一个带有长字符ID变量的样本数据集。我们将介绍一个数字ROW变量，我们稍后可以使用该变量将设计矩阵与输入数据合并。

data have;
   input id :$21. education_lvl $ income_lvl $ ;
   row+1;
datalines;
1 A A
2 B B
3 C C
;

您可以将变量列表设置为宏变量，因为我们需要在多个位置使用它。

%let varlist=education_lvl income_lvl;

使用PROC GLMMOD生成设计矩阵和我们稍后用于生成用户友好变量名称的参数列表。

proc glmmod data=have outdesign=design outparm=parm noprint;
    class &varlist;
    model row=&varlist / noint ;
run;

现在让我们使用参数列表为临时文本文件生成重命名语句。

filename code temp;
data _null_;
  set parm end=eof;
  length rename $65 ;
  rename = catx('=',cats('col',_colnum_),catx('_',effname,of &varlist));
  file code ;
  if _n_=1 then put 'rename ' ;
  put @3 rename ;
  if eof then put ';' ;
run;

现在让我们与输入数据合并，并重命名设计矩阵中的变量。

data want;
  merge have design;
  by row ;
%inc code / source2;
run;