Question

我需要一个执行此操作的功能：

>>> func (+1) [1,2,3]
[[2,2,3],[2,3,3],[2,3,4]]

我的实际案例更复杂，但这个例子显示了问题的要点。主要的区别在于，实际上使用索引是不可行的。 List应为Traversable或Foldable。

编辑：这应该是该功能的签名：

func :: Traversable t => (a -> a) -> t a -> [t a]

更接近我真正想要的是与traverse相同的签名，但无法弄清楚我必须使用的功能，以获得所需的结果。

func :: (Traversable t, Applicative f) :: (a -> f a) -> t a -> f (t a)

Answer 1

看起来@Benjamin Hodgson误读了您的问题，并认为您希望f应用于每个部分结果中的单个元素。因此，你最终认为他的方法不适用于你的问题，但我认为确实如此。请考虑以下变体：

import Control.Monad.State

indexed :: (Traversable t) => t a -> (t (Int, a), Int)
indexed t = runState (traverse addIndex t) 0
  where addIndex x = state (\k -> ((k, x), k+1))

scanMap :: (Traversable t) => (a -> a) -> t a -> [t a]
scanMap f t =
  let (ti, n) = indexed (fmap (\x -> (x, f x)) t)
      partial i = fmap (\(k, (x, y)) -> if k < i then y else x) ti
  in  map partial [1..n]

这里，indexed在状态monad中运行，为可遍历对象的元素添加递增索引（并获得“免费”的长度，无论这意味着什么）：

> indexed ['a','b','c']
([(0,'a'),(1,'b'),(2,'c')],3)

再次，正如Ben指出的那样，也可以使用mapAccumL：

来编写

indexed = swap . mapAccumL (\k x -> (k+1, (k, x))) 0

然后，scanMap获取可遍历对象，将其fmaps到类似的前/后对结构，使用indexed对其进行索引，并应用partial函数序列，其中partial i为第一个i元素选择“afters”，为其余元素选择“befores”。

> scanMap (*2) [1,2,3]
[[2,2,3],[2,4,3],[2,4,6]]

至于将这个从列表推广到其他东西，我无法弄清楚你正在试图用你的第二个签名做什么：

func :: (Traversable t, Applicative f) => (a -> f a) -> t a -> f (t a)

因为如果你把它专门化到一个列表，你会得到：

func' :: (Traversable t) => (a -> [a]) -> t a -> [t a]

并不清楚你在这里要做什么。

Answer 2

在列表中，我将使用以下内容。如果不想要，请随意丢弃第一个元素。

> let mymap f [] = [[]] ; mymap f ys@(x:xs) = ys : map (f x:) (mymap f xs)
> mymap (+1) [1,2,3]
[[1,2,3],[2,2,3],[2,3,3],[2,3,4]]

当使用Foldable将可折叠转换为列表后，这也适用于toList。但是，人们可能仍然希望有更好的实现来避免这一步骤，特别是如果我们想要保留原始的可折叠类型，而不仅仅是获取列表。

Answer 3

根据你的问题，我只是称它为func，因为我无法想到一个更好的名字。

import Control.Monad.State

func f t = [evalState (traverse update t) n | n <- [0..length t - 1]]
    where update x = do
            n <- get
            let y = if n == 0 then f x else x
            put (n-1)
            return y

我们的想法是update从n倒数，当它达到0时，我们应用f。我们将n保留在状态monad中，以便traverse可以在遍历遍历时n探测{。}}。

ghci> func (+1) [1,1,1]
[[2,1,1],[1,2,1],[1,1,2]]

你可以使用mapAccumL来保存一些击键，这是一个HOF，可以捕获状态monad中遍历的模式。

Answer 4

听起来有点像没有焦点的拉链;也许是这样的：

data Zippy a b = Zippy { accum :: [b] -> [b], rest :: [a] }

mapZippy :: (a -> b) -> [a] -> [Zippy a b]
mapZippy f = go id where
  go a [] = []
  go a (x:xs) = Zippy b xs : go b xs where
    b = a . (f x :)

instance (Show a, Show b) => Show (Zippy a b) where
  show (Zippy xs ys) = show (xs [], ys)


mapZippy succ [1,2,3]
-- [([2],[2,3]),([2,3],[3]),([2,3,4],[])]

（为了效率而使用差异列表）

转换为折叠看起来有点像paramorphism：

para :: (a -> [a] -> b -> b) -> b -> [a] -> b
para f b [] = b
para f b (x:xs) = f x xs (para f b xs)

mapZippy :: (a -> b) -> [a] -> [Zippy a b]
mapZippy f xs = para g (const []) xs id where
  g e zs r d = Zippy nd zs : r nd where
    nd = d . (f e:)

对于任意遍历，有一个很酷的时间传播状态变换器，称为Tardis，可以让你向前和向后传递状态：

mapZippy :: Traversable t => (a -> b) -> t a -> t (Zippy a b)
mapZippy f = flip evalTardis ([],id) . traverse g where
  g x = do
    modifyBackwards (x:)
    modifyForwards (. (f x:))
    Zippy <$> getPast <*> getFuture

显示中间状态时的映射

4 个答案: