Question

我正在尝试计算列表中反转的数量。谓词inversion(+L,-N)将N统一到该列表中的反转次数。反转定义为X > Y，X出现在列表中的Y之前（除非X或Y为{{1} }}）。例如：

对于我正在使用的内容，列表将始终包含9个元素，并始终唯一地包含数字?- inversions([1,2,3,4,0,5,6,7,8],N). N = 0. ?- inversions([1,2,3,0,4,6,8,5,7],N). N = 3.。

我对Prolog很新，我试图尽可能简洁和优雅;似乎DCG可能会有很大帮助。我读了官方定义和一些教程网站，但仍然没有放弃了解它是什么。任何帮助将不胜感激。

Answer 1

这是另一种不使用if_/3留下选择点的解决方案：

inversions([],0).
inversions([H|T], N):-
   if_( H = 0, 
        inversions(T,N),
        ( find_inv(T,H,N1),inversions(T, N2), N #= N1+N2 )
      ).

find_inv([],_,0).
find_inv([H1|T],H,N1):-
   if_( H1=0,
        find_inv(T,H,N1),
        if_( H#>H1, 
             (find_inv(T,H,N2),N1 #= N2+1),
             find_inv(T,H,N1) 
           )
       ).

#>(X, Y, T) :-
   (  integer(X),
      integer(Y)
   -> ( X > Y
      -> T = true
      ;  T = false
      )
   ;  X #> Y,
      T = true
   ;  X #=< Y,
      T = false
   ).

Answer 2

我不太确定DCG在这里会有所帮助。虽然我们正在处理一个序列，但在查看每个元素时，每个点都会检查整个列表。

这是一种CLPFD方法，它实现了用于反演的“天真”算法，因此它透明且简单，但效率不高（它的 O （n ^ 2））。有一个更有效的算法（ O （n log n））涉及divide and conquer方法，我将在下面进一步说明。

:- use_module(library(clpfd)).

inversions(L, C) :-
    L ins 0..9,
    all_distinct(L),
    count_inv(L, C).

% Count inversions    
count_inv([], 0).
count_inv([X|T], C) :-
    count_inv(X, T, C1),     % Count inversions for current element
    C #= C1 + C2,            % Add inversion count for the rest of the list
    count_inv(T, C2).        % Count inversions for the rest of the list

count_inv(_, [], 0).
count_inv(X, [Y|T], C) :-
    (   X #> Y, X #> 0, Y #> 0
    ->  C #= C1 + 1,         % Valid inversion, count it
        count_inv(X, T, C1)
    ;   count_inv(X, T, C)
    ).

?- inversions([1,2,3,4,0,5,6,7,8],N).
N = 0 ;
false.

?- inversions([1,2,3,0,4,6,8,5,7],N).
N = 3 ;
false.

?-  inversions([0,2,X],1).
X = 1 ;
false.

它确实留下了一个选择点，正如你所看到的，我还没有整理出来。

<小时/> 这是 O （n log n）解决方案，它使用排序/合并算法。

inversion([], [], 0).
inversion([X], [X], 0).
inversion([HU1, HU2|U], [HS1, HS2|S], C) :- % Ensure list args have at least 2 elements
    split([HU1, HU2|U], L, R),
    inversion(L, SL, C1),
    inversion(R, SR, C2),
    merge(SL, SR, [HS1, HS2|S], C3),
    C #= C1 + C2 + C3.

% Split list into left and right halves
split(List, Left, Right) :-
    split(List, List, Left, Right).
split(Es, [], [], Es).
split(Es, [_], [], Es).
split([E|Es], [_,_|T], [E|Ls], Right) :-
    split(Es, T, Ls, Right).

% merge( LS, RS, M )
merge([], RS, RS, 0).
merge(LS, [], LS, 0).
merge([L|LS], [R|RS], [L|T], C) :-
    L #=< R,
    merge(LS, [R|RS], T, C).
merge([L|LS], [R|RS], [R|T], C) :-
    L #> R, R #> 0 #<==> D, C #= C1+D,
    merge([L|LS], RS, T, C1).

您可以忽略第二个参数，即排序列表（如果您想要的只是反转计数，则只是副作用）。

Answer 3

这是定义关系的另一种可能性。首先，#</3和#\=/3可以这样定义：

:- use_module(library(clpfd)).

bool_t(1,true).
bool_t(0,false).

#<(X,Y,Truth)  :- X #< Y #<==> B, bool_t(B,Truth).
#\=(X,Y,Truth)  :- X #\= Y #<==> B, bool_t(B,Truth).

基于此，if_/3和(',')/3可以定义谓词inv_t/3，在反转的情况下产生true，否则根据OP给出的定义产生false ：

inv_t(X,Y,T) :-
   if_(((Y#<X,Y#\=0),X#\=0),T=true,T=false).

随后可以这样描述实际关系：

list_inversions(L,I) :-
   list_inversions_(L,I,0).

list_inversions_([],I,I).
list_inversions_([X|Xs],I,Acc0) :-
   list_x_invs_(Xs,X,I0,0),
   Acc1 #= Acc0+I0,
   list_inversions_(Xs,I,Acc1).

list_x_invs_([],_X,I,I).
list_x_invs_([Y|Ys],X,I,Acc0) :-
   if_(inv_t(X,Y),Acc1#=Acc0+1,Acc1#=Acc0),
   list_x_invs_(Ys,X,I,Acc1).

因此，OP给出的示例查询确定性地成功：

?- list_inversions([1,2,3,4,0,5,6,7,8],N).
N = 0.

?- list_inversions([1,2,3,0,4,6,8,5,7],N).
N = 3.

Answer 4

使用clpfd et automaton / 8我们可以写

:- use_module(library(clpfd)).

inversions(Vs, N) :-
             Vs ins 0..sup,
             variables_signature(Vs, Sigs),
             automaton(Sigs, _, Sigs,
                       [source(s),sink(i),sink(s)],
                       [arc(s,0,s), arc(s,1,s,[C+1]), arc(s,1,i,[C+1]),
                        arc(i,0,i)],
                       [C], [0], [N]),
            labeling([ff],Vs).

variables_signature([], []).

variables_signature([V|Vs], Sigs) :-
            variables_signature_(Vs, V, Sigs1),
            variables_signature(Vs, Sigs2),
            append(Sigs1, Sigs2, Sigs).

variables_signature_([], _, []).

variables_signature_([0|Vs], Prev, Sigs) :-
      variables_signature_(Vs,Prev,Sigs).

variables_signature_([V|Vs], Prev, [S|Sigs]) :-
      V #\= 0,
      % Prev #=< V #<==> S #= 0,
      % modified after **false** remark 
      Prev #> V #<==> S,
      variables_signature_(Vs,Prev,Sigs).

示例：

?- inversions([1,2,3,0,4,6,8,5,7],N).
N = 3 ;
false.

?- inversions([1,2,3,0,4,5,6,7,8],N).
N = 0 ;
false.

?- inversions([0,2,X],1).
X = 1.

Answer 5

这种特定于应用程序的约束通常可以使用确定约束（其真值被反映到0/1变量中的约束）构建。这导致了一种相对自然的表达式，如果满足您想要计算的条件，则B为1：

:- lib(ic).

inversions(Xs, N) :-
    ( fromto(Xs, [X|Ys], Ys, [_]), foreach(NX,NXs) do
        ( foreach(Y,Ys), param(X), foreach(B,Bs) do
            B #= (X#\=0 and Y#\=0 and X#>Y)
        ),
        NX #= sum(Bs)       % number of Ys that are smaller than X
    ),
    N #= sum(NXs).

此代码适用于ECLiPSe。

Answer 6

在SWI-Prolog中，包含图书馆aggregate和lists：

inversions(L,N) :-
    aggregate_all(count, (nth1(P,L,X),nth1(Q,L,Y),X\=0,Y\=0,X>Y,P<Q), N).

这两个库都是自动加载的，无需明确包含它们。

如果你想要更通用的东西，你可以在自动机部分的库（clpfd）中看到一些有用的想法。但我会尝试用更简单的术语重写您的规范，使用element / 3而不是nth1 / 3。

修改的

在@false评论之后，我尝试了对不平等运算符的一些变化，但是我没有尝试过能够解决有问题的查询。然后我再次尝试了原始的想法，以充分利用元素/ 3。结果如下：

:- use_module(library(clpfd)).

inversions(L) :-
    L ins 0..8,
    element(P,L,X),
    element(Q,L,Y),
    X #\= 0, Y #\= 0, X #> Y, P #< Q,
    label([P,Q]).

inversions(L,N) :-
    aggregate(count, inversions(L), N) ; N = 0.

最后一行label([P,Q])是正确具体化的关键：现在我们可以确定X值。

?- inversions([0,2,X],1).
X = 1.

DCG和Prolog中列表的反转

6 个答案: