Question

我正在尝试通过搜索和替换来修改列表，我想知道如何搜索列表中的搜索字词作为列表？

让我说我有一个清单[1,2,3,4]我想挑出2和3并用5,6替换它理想情况下，我可以有一个谓词：

search_and_replace(Search_Term, Replace_Term, Target_List, Result_List).

eg.

search_and_replace([2,3], [5,6], [1,2,3,4], Result_List), write(Result_List).

Answer 1

让我假设你想用另一个列表替换列表中的~~子序列~~子串。

以下是如何执行此操作的一般方法。您可能想要插入该计划的进一步条件。

replacement(A, B,  Ag, Bg) :-
   phrase((seq(S1),seq(A),seq(S2)), Ag),
   phrase((seq(S1),seq(B),seq(S2)), Bg).

seq([]) --> [].
seq([E|Es]) --> [E], seq(Es).

并且，是的，这可以进行一些优化 - 甚至是它的终止属性会盈利的。但概念清晰度是一个非常宝贵的价值......

编辑：您的示例查询：

?- replacement([2,3], [5,6], [1,2,3,4], Xs).
Xs = [1, 5, 6, 4] ;
false.

Answer 2

您可以按如下方式使用追加/ 2 ：

replace(ToReplace, ToInsert, List, Result) :-
    once(append([Left, ToReplace, Right], List)),
    append([Left, ToInsert, Right], Result).

使用或不使用一次/ 1 ，具体取决于您是否需要所有可能性。

要用以下内容替换所有出现的内容：

replace(ToReplace, ToInsert, List, Result) :-
    replace(ToReplace, ToInsert, List, [], Result).
replace(ToReplace, ToInsert, List, Acc, Result) :-
    append([Left, ToReplace, Right], List),
    append([Acc, Left, ToInsert], NewAcc),
    !,
    replace(ToReplace, ToInsert, Right, NewAcc, Result).
replace(_ToReplace, _ToInsert, [], Acc, Acc).

如何在Prolog中搜索并替换列表中的另一个子列表？

2 个答案: