Question

如果我在TCL中有一个过程或命令，参数数量可变，如果列表的元素作为输入，则可以使用“splatter”运算符，例如：

set a [list "ko" ]
set m [ list "ok" "bang" ]
lappend a {*}$m

但是，如果我想“两次飞溅”怎么办？即，压平2级？按顺序使用它两次不起作用：

set a [list "ko" ]
set m [ list [ list "ok" ] [ list "bang" ] ]
lappend a {*}{*}$m

额外字符会出错。

Answer 1

您已经注意到{*}（故意）并没有走两步。

你的具体例子并不能说明问题，所以我建议：

set a [list "ko" ]
set m [list [list "a b" "c d"] [list "e f" "g h"]]
lappend a {*}$m

在这里，我们将a设置为ko {{a b} {c d}} {{e f} {g h}}。这不是你想要的。但我们可以这样做：

lappend a {*}[concat {*}$m]

这给出了这个：ko {a b} {c d} {e f} {g h}。看起来是正确的。

但我们真的在这里做正确的事吗？让我们用我们超级秘密的内省探测器representation命令进行内窥探：

% tcl::unsupported::representation $m
value is a list with a refcount of 4, object pointer at 0x10085ec50, internal representation 0x103016790:0x0, string representation "{{a b} {c d}}..."
% tcl::unsupported::representation [concat {*}$m]
value is a string with a refcount of 1, object pointer at 0x10085de10, internal representation 0x1030052d0:0x10085f190, string representation "{a b} {c d} {..."

哦，哦！我们已经失去了名单。它不是灾难，但它不是我们想要的。我们应该真的这样做：

foreach sublist $m {
    lappend a {*}$sublist
}

嗯，那更多的代码但保留了list-ness（如果碰巧在叶子上有宝贵的类型会很好;核心Tcl没有这样珍贵的类型，但有些扩展会这样做）

我们可以比较时间：

% time {
    set a [list "ko" ]
    set m [list [list "a b" "c d"] [list "e f" "g h"]]
    lappend a {*}[concat {*}$m]
} 10000
2.852789 microseconds per iteration
% time {
    set a [list "ko" ]
    set m [list [list "a b" "c d"] [list "e f" "g h"]]
    foreach sublist $m {
        lappend a {*}$sublist
    }
} 10000
4.022959 microseconds per iteration

...喔

% time {apply {{} {
    set a [list "ko" ]
    set m [list [list "a b" "c d"] [list "e f" "g h"]]
    lappend a {*}[concat {*}$m]
}}} 10000
2.4486125 microseconds per iteration
% time {apply {{} {
    set a [list "ko" ]
    set m [list [list "a b" "c d"] [list "e f" "g h"]]
    foreach sublist $m {
        lappend a {*}$sublist
    }
}}} 10000
1.6870501 microseconds per iteration

哈！类型正确的在程序（类似上下文）中更好。

Answer 2

{*}语法并未真正压缩列表本身。 Flattening是一个执行级活动，而参数扩展是一个解析级活动。

% set a a
% lappend a {*}{{a b} {c d}}

在此示例中，列表{{a b} {c d}}中的项目作为两个单独的参数拼接到命令行中：

% lappend a {a b} {c d}
a {a b} {c d}

如果你需要再压平一个级别，你应该在扩展之间使用命令：

% lappend a {*}[concat {*}{{a b} {c d}}]
a a b c d

文档： concat， lappend， {*} (syntax)， Summary of Tcl language syntax

两级飞溅TCL

2 个答案: