Question

我有包含

的TEI（文本编码倡议）文件

    if(e.getSource() instanceof JRadioButton)
   {

我希望将其转换为：

<div>
  <p>
     some text, and maybe nodes <note>A note</note><lb />
     and some more text<lb />
     final line without lb
  </p>
</div>

使用

将p转换为lg是微不足道的

<div>
  <lg>
     <l>some text, and maybe nodes <note>A note</note></l>
     <l>and some more text</l>
     <l>final line without lb</l>
  </lg>
</div>

但其他人无法弄清楚该怎么做。将一系列节点转换为新父节点的子节点。

如果有xslt 1.0的解决方案，那就太棒了。

Answer 1

这是你可以看到它的另一种方式。它使用键将每个节点链接到最近的前一个lb分隔符。这使您可以通过前导分隔符的唯一ID来获取每个组（第一个除外）：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:key name="following-nodes" match="node()[not(self::lb)]" use="generate-id(preceding-sibling::lb[1])" />

<xsl:template match="p[lb]">
    <lg>
        <l>
            <xsl:apply-templates select="lb[1]/preceding-sibling::node()"/>
        </l>
        <xsl:for-each select="lb">
            <l>
                <xsl:apply-templates select="key('following-nodes', generate-id())"/>
            </l>
        </xsl:for-each>
    </lg>
</xsl:template>

</xsl:stylesheet>

此示例不使用命名空间，因为您的问题没有定义它们。

Answer 2

您可以在此处使用名为Muenchian grouping的技术。在这种情况下，您可以将p元素的子节点按照跟随它们的lb元素的数量进行分组

<xsl:key name="p-nodes" match="tei:p/node()" use="concat(generate-id(..), '|', count(following-sibling::tei:lb))" />

要获取每个组中的第一个节点，它将代表您想要输出的每个l，您可以选择它们......

<xsl:for-each
     select="node()[generate-id() = generate-id(key('p-nodes', concat($parentId, '|', count(following-sibling::tei:lb)))[1])]">

要输出<l>标签本身以及该组的内容，请再次使用该密钥...

<l><xsl:apply-templates select="key('p-nodes', concat($parentId, '|', count(following-sibling::tei:lb)))[not(self::tei:lb)]" /></l>

尝试使用此XSLT（显然更改tei前缀的名称空间以匹配XML中的实际名称）

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" xmlns:tei="tei">
    <xsl:output method="xml" indent="yes" />

    <xsl:key name="p-nodes" match="tei:p/node()" use="concat(generate-id(..), '|', count(following-sibling::tei:lb))" />

    <xsl:template match="tei:div/tei:p">
       <lg>
            <xsl:variable name="parentId" select="generate-id()" />
            <xsl:for-each select="node()[generate-id() = generate-id(key('p-nodes', concat($parentId, '|', count(following-sibling::tei:lb)))[1])]">
                <l><xsl:apply-templates select="key('p-nodes', concat($parentId, '|', count(following-sibling::tei:lb)))[not(self::tei:lb)]" /></l>
            </xsl:for-each>
       </lg>
    </xsl:template>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

在http://xsltransform.net/gWEamMf

中查看此操作

将TEI p转换为lg

2 个答案: