Question

我在actionscript3工作，因为我自学成才，我认为我养成了一些坏习惯，包括在时间轴上编码和使用多个场景。

我希望能够纠正这个问题，因为我正在开展一个更大的项目。

根据我的阅读，将多个.fla文件链接在一起是一种更好的做法，每种文件都有自己的文档类。这是对的吗？

如果是这样，我如何将一个.fla加载到其文档类中，然后将其链接到后续的.fla文件中（而不是使用场景）？或者我误解了推荐的内容？

谢谢！

Answer 1

除非您具有以下任何前提条件，否则将应用程序拆分为多个可加载模块是没有意义的：

您有智能资源管理来加载和卸载内容
如果你把所有东西都放在一个文件中，那么它在设计时就太大而且很难处理，或者编译时间太长了

使用场景的常规AS3替代方法是创建/销毁内容实例并使用主文档类作为其管理器。您可以在库中设计内容并为它们创建行为AS3类。可以说，你有两个内容类A和B.一开始，经理应该显示其中一个并等待信号显示下一个：

private var APage:A;
private var BPage:B;

gotoA();

function gotoA():void
{
    if (BPage)
    {
        BPage.destroy();
        removeChild(BPage);
        BPage.removeEventListener(Event.CLOSE, gotoA);
    }

    APage = new A;
    APage.addEventListener(Event.CLOSE, gotoB);
    addChild(APage);
}

function gotoB():void
{
    if (APage)
    {
        APage.destroy();
        removeChild(APage);
        APage.removeEventListener(Event.CLOSE, gotoB);
    }

    BPage = new B;
    BPage.addEventListener(Event.CLOSE, gotoA);
    addChild(BPage);
}

因此，A和B都应该有各自的方法.destroy（）释放已使用的资源，取消订阅事件中的方法，删除显示对象等等，并且它们都应该在它们完成后触发Event.CLOSE。 / p>

如果你有很多这样的页面，你需要采用更多的算法方法。例如，要创建将与管理器交互的类BasicPage，并在已声明的所有页面中使用所需的方法：

package
{
    import flash.display.Sprite;

    class BasicPage extends Sprite
    {
        // A reference to the page manager instance.
        public var Manager:PageManager;

        public function destroy():void
        {
            while (numChildren > 0) removeChildAt(0);

            Manager = null;
        }

        // Subclasses will have an access to this method to tell manager to show another page.
        protected function showOtherPage(pageClass:Class):void
        {
            Manager.showPage(pageClass);
        }

        // A method that is called by manager when everything is ready.
        // If page should take any actions on start it is a good idea to override this method.
        public function startEngine():void
        {
        }
    }
}

然后，示例页面A：

package
{
    import flash.events.MouseEvent;

    public class A extends BasicPage
    {
        // Lets say, class A in library have a designed button named Click.
        public var Click:SimpleButton;

        // We have things to undo here.
        override public function destroy():void
        {
            Click.removeEventListener(MouseEvent.CLICK, onClick);
            Click = null;

            // Pass the destruction to superclass so it wraps its existence either.
            super.destroy();
        }

        override public function startEngine():void
        {
            Click.addEventListener(MouseEvent.CLICK, onClick);
        }

        private function onClick(e:MouseEvent):void
        {
            // Lets use inherited method to show other page.
            showOtherPage(B);
        }
    }
}

所以，PageManager就像：

package
{
    public class PageManager extends Sprite
    {
        private var Page:BasicPage;

        // constructor
        function PageManager()
        {
            super();
            showPage(A);
        }

        function showPage(pageClass:Class):void
        {
            if (Page)
            {
                Page.destroy();
                removeChild(Page);
                Page = null;
            }

            Page = new pageClass;
            Page.Manager = this;

            addChild(Page);
            Page.startEngine();
        }
    }
}

这一切看起来都很吓人，但事实并非如此。 PageManager将始终具有当前页面，一旦需要显示另一页面，当前将被销毁。每个页面类都倾向于它自己的内容，这使编码更简单，因为你不需要看到整个图片。如果您需要任何持久性数据，请将其保存在PageManager中，这样每个页面都可以访问数据而无需页面相互通信。

使用文档类在动作脚本中将fla文件链接在一起

1 个答案: