Question

假设以下特定情况。

我们有一个平等的定义：

Inductive eqwal {A : Type} (x : A) : A -> Prop :=
    eqw_refl : eqwal x x.

和peano nats：

Inductive nawt : Prop :=
    | zewro : nawt
    | sawc  : nawt -> nawt.

我们在nat上定义添加：

Fixpoint plaws (m n : nawt) : nawt :=
    match m with
      | zewro => n
      | sawc m' => sawc (plaws m' n)
    end.

现在我们要证明零从正确的wrt中立。求和：

Theorem neutral_r : forall n : nawt, eqwal (plaws n zewro) n.

可悲的是，以下原型的最后一行说“错误：n用于结论。”。

Proof.
intros.
induction n. - this is the culprit

官方文档中的错误并不多，我有点困惑 - 为什么会出现这种错误？

使用标准库，我可以轻松证明这个定理：

Theorem neutral_r : forall n : nat,
  n + 0 = n.
Proof.
  induction n; try reflexivity.
  cbn; rewrite IHn; reflexivity.
Qed.

Answer 1

问题是您使用排序nawt而不是Prop或Type定义了Set。默认情况下，为命题生成的归纳原则不允许我们证明这些命题的证明。考虑为nawt生成的默认归纳原则：

Check nawt_ind.
> nawt_ind : forall P : Prop, P -> (nawt -> P -> P) -> nawt -> P

由于nawt_ind量化超过Prop而未超过nat -> Prop，我们无法用它来证明您的目标。

解决方案是设置一些可以改变Coq默认行为的选项，如下面的脚本所示。

Inductive eqwal {A : Type} (x : A) : A -> Prop :=
    eqw_refl : eqwal x x.

Unset Elimination Schemes.

Inductive nawt : Prop :=
    | zewro : nawt
    | sawc  : nawt -> nawt.

Scheme nawt_ind := Induction for nawt Sort Prop.

Set Elimination Schemes.

Fixpoint plaws (m n : nawt) : nawt :=
    match m with
      | zewro => n
      | sawc m' => sawc (plaws m' n)
    end.

Theorem eqwal_sym {A : Type} (x y : A) : eqwal x y -> eqwal y x.
Proof. intros H. destruct H. constructor. Qed.

Theorem neutral_r : forall n : nawt, eqwal (plaws n zewro) n.
Proof.
intros. induction n as [|n IH]; simpl.
- constructor.
- apply eqwal_sym in IH. destruct IH. constructor.
Qed.

Elimination Schemes选项使Coq自动为数据类型和命题生成归纳原则。在这个脚本中，我只是将其关闭，并使用Scheme命令为nawt生成正确的归纳原则。要使induction策略起作用，请务必将此原则命名为nawt_ind：这是Coq生成的默认名称，是induction查找时的名称。调用。

话虽这么说，我通常建议不要在Prop而不是Type中定义一种自然数字，因为Coq对如何使用Prop中的内容施加限制。例如，无法显示zewro与sawc zewro不同。

为什么不能对结论中使用的术语进行归纳？

1 个答案: