如何强制Excel中输入的任何值转换为负数

Question

如何强制Excel中的任何数字转换为否定数字？

例如，如果用户在A1中输入-10，那么它应该什么也不做，如果输入10，则应该* -1转换为负数。

我已经将以下自定义单元格格式应用于整个工作表：＃，## 0.00_;（＃，## 0.00）表示任何负数都显示在括号中。但A1只能包含一个负数，所以如果用户输入正数，我希望它自动转换为负数。

我该怎么做？

Answer 1

在工作表代码区域中包含以下事件宏：

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim A1 As Range
    Set A1 = Range("A1")
    If Intersect(Target, A1) Is Nothing Then Exit Sub
    If IsNumeric(A1) Then
        If A1 < 0 Then Exit Sub
        Application.EnableEvents = False
            A1 = -A1
        Application.EnableEvents = True
    End If
End Sub

与数据验证不同，它不会拒绝正输入，只会使其成为负数。

修改＃1：

因为它是工作表代码，所以很容易安装和自动使用：

1. 右键单击Excel窗口底部附近的选项卡名称
2. 选择查看代码 - 这会打开一个VBE窗口
3. 粘贴内容并关闭VBE窗口

如果您有任何疑虑，请先在试用工作表上试用。

如果保存工作簿，宏将随之保存。 如果您在2003年之后使用的是Excel版本，则必须保存 该文件为.xlsm而不是.xlsx

删除宏：

1. 按上述方式调出VBE窗口
2. 清除代码
3. 关闭VBE窗口

要了解有关宏的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/getstarted.htm

和

http://msdn.microsoft.com/en-us/library/ee814735(v=office.14).aspx

要了解有关事件宏（工作表代码）的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/event.htm

必须启用宏才能使其生效！

修改＃2：

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim negatives As Range, r As Range, rLOOK As Range
    Set negatives = Range("negatives")
    Set rLOOK = Intersect(negatives, Target)
    If rLOOK Is Nothing Then Exit Sub

    For Each r In rLOOK
        If IsNumeric(r) Then
            If r > 0 Then
                Application.EnableEvents = False
                    r.Value = -r.Value
                Application.EnableEvents = True
            End If
        End If
    Next r
End Sub

我们在这里：

• 得到交叉点
• 测试交叉路口
• 循环交叉路口

Answer 2

您可以使用ABS作为绝对值（正值）

=-ABS(A1)