Question

我用来编写几个程序（带内存）的习语如下：

p1 :: State (Int, String) ()
p1 = do
    (a, b) <- get
    ... do something ...
    put (a', b)

p2 :: State (Int, String) ()
p2 = do
    (a, b) <- get
    ... do something else ...
    put (a, b')

main = do
    ... initializing a0 b0 ...
    print . flip evalState (a0, b0)
          . sequence $ replicate 10 p1 ++ repeat p2

然而，随着状态变量的数量增加，这很快变得比必要的更冗长：

p1 :: State (Int, String, Bool, Int, String, Bool) ()
p1 = do
    (a, b, c, d, e, f) <- get
    ... do something ...
    put (a, b, c', d, e, f')

p2 :: State (Int, String, Bool, Int, String, Bool) ()
p2 = do
    (a, b, c, d, e, f) <- get
    ... do something ...
    put (a', b', c, d, e, f)

main = do
    print . flip evalState (a0, b0, c0, d0, e0, f0)
          . sequence $ replicate 10 p1 ++ repeat p2

正如我想知道的那样，是否有办法只更新一些状态变量而不必参考所有未使用的变量？我在考虑类似IORef但State（事实上有一个包stateref），但我不确定是否已有一些其他人有的常用习语一直在使用。

Answer 1

这似乎是lenses的工作。特别是Control.Lens.Tuple模块以及.=和use：

p1 = do
   a <- use _1
   -- do something --
   _1 .= a'

但是，如果你用你所在州的名称给出的东西通常会更好，例如。

{-# LANGUAGE TemplateHaskell #-

data Record = MkRecord { _age :: Int
                       , _name :: String
                       , _programmer :: Bool
                       } deriving (Show, Eq)
makeLenses ''Record

这样，你的领域有更好的名字：

p1 = do
   a <- use age
   -- do something --
   age .= a'

请注意，如果您不想使用镜头，这仍然可以帮到您，因为您可以使用记录语法来更新数据：

 p1 = do
      r <- get
      let a = _age r
      --- do something
      put $ r{_age = a'}

Answer 2

这是一个很好的情况，使用记录，gets和modify函数来操纵状态的子部分：

data Env = Env
  { envNumber :: Int
  , envText :: String
  }

p1 :: State Env ()
p1 = do
    a <- gets envNumber
    -- ...
    modify $ \r -> r { envNumber = a' }

p2 :: State Env ()
p2 = do
    b <- gets envText
    -- ...
    modify $ \r -> r { envText = b' }

gets将纯粹的getter函数转换为状态操作：

gets :: (s -> a) -> State s a
envNumber :: Env -> Int
gets envNumber :: State Env Int

modify将纯更新函数转换为状态操作：

modify :: (s -> s) -> State s ()
(\r -> r { envText = b' }) :: Env -> Env
modify (\r -> ...) :: State Env ()

Answer 3

lens的{{3}}将State monad中的计算提升为以“更大”State monad运行的计算。

zoom :: Lens' s t -> State t a -> State s a

所以，给定一个“大”状态：

data Big = Big {
    _big1 :: Medium,
    _big2 :: Medium
}
data Medium = Medium {
    _medium1 :: Small,
    _medium2 :: Small
}
data Small = Small { _small :: Int }

makeLenses ''Big
makeLenses ''Medium
makeLenses ''Small

你可以“放大”状态的一部分：

incr :: State Int ()
incr = id += 1

incrSmall :: State Big ()
incrSmall = zoom (big2.medium1.small) incr

当然，这可以使用lens的内置zoom combinator处理大元组和记录。

zoom的真实类型签名比我上面引用的简单签名更通用。它使用MonadState约束在monad变换器堆栈下工作，而不是在State中专门工作。

如何只更新几个时，如何避免引用所有状态变量？

3 个答案: