Question

在许多语言中，可以将正则表达式捕获组分配给一个或多个变量。这也是XQuery的情况吗？到目前为止我们所做的最好的事情就是通过捕获组来取代，但这似乎并不是最漂亮的选择。

这就是我们现在所拥有的：

let $text := fn:replace($id, '(.+)(\d+)', '$1');
let $snr := fn:replace($id, '(.+)(\d+)', '$2');

哪个有效。但我希望会有这样的事情：

let ($text, $snr) := fn:matches($id, '(.+)(\d+)');

是否存在（或类似的东西）？

Answer 1

Plain XQuery 1.0不支持返回匹配组。这个缺点已在XQuery function library which provides functx:get-matches中得到解决，但实施并不是一种有效的方法。

XQuery 3.0知道非常强大的函数fn:analyze-string。该函数返回匹配和非匹配部分，如果在正则表达式中定义了匹配组，也会按匹配组拆分。

上面链接的Marklogic文档中的一个示例，但该函数来自标准的XPath / XQuery 3.0函数库，也可用于其他XQuery 3.0实现：

fn:analyze-string('Tom Jim John',"((Jim) John)")

=>
<s:analyze-string-result>
  <s:non-match>Tom </s:non-match>
  <s:match>
    <s:group nr="1">
    <s:group nr="2">Jim</s:group>
    John
    </s:group>
  </s:match>
</s:analyze-string-result>

如果您不支持XQuery 3.0：某些引擎提供类似的实现定义函数或允许使用Java代码等后端函数，请在这种情况下阅读XQuery引擎的文档。

Answer 2

如果您知道捕获组中没有出现某个字符，您可以在组之间使用替换字符，然后在XQuery 1中对其进行标记。

例如：

tokenize(replace("abc1234", "(.+)(\d+)", "$1-$2"), "-")

确保替换删除组之前/之后的所有内容：

tokenize(replace("abc1234", "^.*?(.+?)(\d+).*?$", "$1-$2"), "-")

您可以通过使用string-join为任何分隔符创建替换模式（例如“$ 1- $ 2- $ 3- $ 4”）来将其概括为函数：

declare function local:get-matches($input, $regex, $separator, $groupcount) {
  tokenize(replace($input, concat("^.*?", $regex, ".*?$"), string-join(for $i in 1 to $groupcount return concat("$", $i), $separator)), $separator, "q" )
};
local:get-matches("abc1234", "(.+?)(\d+)", "|", 2)

如果您不想自己指定分隔符，则需要一个函数来查找分隔符。比输入字符串长的每个字符串都不能出现在捕获组中，因此您始终可以使用较长的分隔符找到一个字符串：

declare function local:get-matches($input, $regex, $separator) {
  if (contains($input, $separator)) then local:get-matches($input, $regex, concat($separator, $separator))
  else 
    let $groupcount := count(string-to-codepoints($regex)[. = 40])
    return tokenize(replace($input, concat("^.*?", $regex, ".*?$"), string-join(for $i in 1 to $groupcount return concat("$", $i), $separator)), $separator, "q" )
};
declare function local:get-matches($input, $regex) {
  local:get-matches($input, $regex, "|#☎")
};
local:get-matches("abc1234", "(.+?)(\d+)")

将捕获组分配给XQuery中的变量

2 个答案: