Question

我有以下类型：

data S req rsp = Done rsp | Next req (rsp -> S req rsp)

这个想法是将它用作网络通信的纯粹表示，即：

... Next GetUser $ \uid -> Next (Login uid) $ \success -> Done success

然后由一些不纯的函数eval评估。

现在，这是什么（如果有的话？）就我所知，这不是一个单子，也不是箭头。它似乎是stream / pipe / automaton / fsm和continuation monad之间的东西。这让我觉得这种类型的东西可能有更好的代表性，但是什么呢？

Answer 1

这是Free Monad。这个想法是你有一个说明的描述，你可以有多个解释器，如eval函数。免费Monad抽象了这个任务的模式。有关详细信息，我建议this great post。

要使您的类型适应Free，我们可以执行以下操作：

{-# LANGUAGE DeriveFunctor #-}

import Control.Monad.Free

data Instruction req rsp next =
  Respond rsp |
  Interact req (rsp -> next)
  deriving (Functor)

type S req rsp =
  Free (Instruction req rsp)

respond :: rsp -> S req rsp ()
respond rsp =
  liftF (Respond rsp)

interact :: req -> S req rsp rsp
interact req =
  liftF (Interact req id)

现在，感谢Free，S req rsp是一个monad，这意味着您现在可以使用respond API撰写interact和Monad个函数。

还有更多内容。可以使用Template Haskell生成respond和interact函数，并使用以下额外代码：

{-# LANGUAGE TemplateHaskell #-}

import Control.Monad.Free.TH

makeFree ''Instruction

Answer 2

您的类型有点像Apfelmus's operational monad，也称为the Freer monad：

data Program inst a where
    Return :: a -> Program inst a
    Bind :: inst a -> (a -> Program inst b) -> Program inst b

instance Monad (Program inst) where
    return = Return
    Return x >>= f = f x
    Bind i next >>= f = Bind i (fmap (>>= f) next)

-- plus the usual Functor and Applicative boilerplate

Program :: (* -> *) -> * -> *表示一系列指令 inst，它们使用其类型参数来指示＆＃34;返回类型＆＃34;在解释器中运行该指令。 Bind构造函数接受一条指令和一个延续，它可以在从解释器接收到指令的结果之后运行。注意a是如何存在量化的，反映了计算中所有中间步骤的类型与整体类型无关的事实。

Program与您的类型之间的重要区别在于响应的类型由指令决定，而不是在整个计算中固定。这使我们能够对每个请求所期望的响应做出更细粒度的保证。

例如，这里的状态monad被写为Program：

data StateI s r where
    Get :: StateI s s
    Put :: s -> StateI s ()

type State s = Program (StateI s)

get :: State s s
get = Bind Get Return
put :: s -> State s ()
put s = Bind (Put s) Return

modify :: (s -> s) -> State s ()
modify f = do
    x <- get
    put (f x)

runState :: State s a -> s -> (s, a)
runState (Return x) s = (s, x)
runState (Bind Get next) s = runState (next s) s
runState (Bind (Put s) next) _ = runState (next ()) s

共同Yoneda引理告诉我们Program与Free是同构的。直观地说，它是基于-> Functor实例的免费monad。对于某些操作（如左关联绑定），Program可能比Free更有效，因为其>>=基于函数组合，而不是可能昂贵fmap ping任意Functor。

这种请求 - 响应类型是否有标准抽象？

2 个答案: