Question

我有以下代码从音频文件创建FFT对象请参阅以下代码：

import ddf.minim.*;
import ddf.minim.analysis.*;

Minim       minim;
AudioPlayer player;
FFT         fft;


void setup(){
  minim = new Minim(this);
  player = minim.loadFile("audio.mp3");
  fft = new FFT( player.bufferSize(), player.sampleRate() ); 
  fft.logAverages(86, 1); 
  fft.window(FFT.HAMMING);
  numZones = fft.avgSize();
}

但现在我想为左右声道创建两个FFT对象。所以最后我想要一个fftLeft =新的FFT（audio.left）和fftRight =新的FFT（audio.right）

我尝试了.getChannel(player.LEFT)方法，但这没有用。有没有人有关于如何做到这一点的提示或建议？

Answer 1

当你运行FFT的forward()方法时，你可以传递你想要的频道。

这样的事情：

//in setup()
fftLeft  = new FFT( player.bufferSize(), player.sampleRate() );
fftRight = new FFT( player.bufferSize(), player.sampleRate() );
//in draw()
fftLeft.forward(player.left);
fftRight.forward(player.right);

这是SoundSpectrum样本的调整版本，附带最小值：

/**
  * An FFT object is used to convert an audio signal into its frequency domain representation. This representation
  * lets you see how much of each frequency is contained in an audio signal. Sometimes you might not want to 
  * work with the entire spectrum, so it's possible to have the FFT object calculate average frequency bands by 
  * simply averaging the values of adjacent frequency bands in the full spectrum. There are two different ways 
  * these can be calculated: <b>Linearly</b>, by grouping equal numbers of adjacent frequency bands, or 
  * <b>Logarithmically</b>, by grouping frequency bands by <i>octave</i>, which is more akin to how humans hear sound.
  * <br/>
  * This sketch illustrates the difference between viewing the full spectrum, 
  * linearly spaced averaged bands, and logarithmically spaced averaged bands.
  * <p>
  * From top to bottom:
  * <ul>
  *  <li>The full spectrum.</li>
  *  <li>The spectrum grouped into 30 linearly spaced averages.</li>
  *  <li>The spectrum grouped logarithmically into 10 octaves, each split into 3 bands.</li>
  * </ul>
  *
  * Moving the mouse across the sketch will highlight a band in each spectrum and display what the center 
  * frequency of that band is. The averaged bands are drawn so that they line up with full spectrum bands they 
  * are averages of. In this way, you can clearly see how logarithmic averages differ from linear averages.
  * <p>
  * For more information about Minim and additional features, visit http://code.compartmental.net/minim/
  */

import ddf.minim.analysis.*;
import ddf.minim.*;

Minim minim;  
AudioPlayer jingle;

FFT fftLogLeft,fftLogRight;

float height3;
float height23;
float spectrumScale = 4;

float centerFrequency;

PFont font;

void setup()
{
  size(512, 480);
  height3 = height/3;
  height23 = 2*height/3;

  minim = new Minim(this);
  jingle = minim.loadFile("jingle.mp3", 1024);

  // loop the file
  jingle.loop();

  // create an FFT object for calculating logarithmically spaced averages
  // left channel
  fftLogLeft = new FFT( jingle.bufferSize(), jingle.sampleRate() );
  fftLogLeft.logAverages( 22, 3 );

  fftLogRight = new FFT( jingle.bufferSize(), jingle.sampleRate() );
  fftLogRight.logAverages( 22, 3 );

  rectMode(CORNERS);
}

void draw()
{
  background(0);
  //run FFT on left channel
  fftLogLeft.forward( jingle.left );
  //run FFT on left channel
  fftLogRight.forward( jingle.right );

  plotFFT(fftLogLeft,height-50,"Left Channel");
  plotFFT(fftLogRight,height,"Right Channel");
}

void plotFFT(FFT fft,float y,String prefix){
  // draw the logarithmic averages
  {
    // since logarithmically spaced averages are not equally spaced
    // we can't precompute the width for all averages
    for(int i = 0; i < fft.avgSize(); i++)
    {
      centerFrequency    = fft.getAverageCenterFrequency(i);
      // how wide is this average in Hz?
      float averageWidth = fft.getAverageBandWidth(i);   

      // we calculate the lowest and highest frequencies
      // contained in this average using the center frequency
      // and bandwidth of this average.
      float lowFreq  = centerFrequency - averageWidth/2;
      float highFreq = centerFrequency + averageWidth/2;

      // freqToIndex converts a frequency in Hz to a spectrum band index
      // that can be passed to getBand. in this case, we simply use the 
      // index as coordinates for the rectangle we draw to represent
      // the average.
      int xl = (int)fft.freqToIndex(lowFreq);
      int xr = (int)fft.freqToIndex(highFreq);

      // if the mouse is inside of this average's rectangle
      // print the center frequency and set the fill color to red
      if ( mouseX >= xl && mouseX < xr )
      {
        fill(255, 128);
        text(prefix + "Logarithmic Average Center Frequency: " + centerFrequency, 5, y - 25);
        fill(255, 0, 0);
      }
      else
      {
          fill(255);
      }
      // draw a rectangle for each average, multiply the value by spectrumScale so we can see it better
      rect( xl, y, xr, y - fft.getAvg(i)*spectrumScale );
    }
  }
}

备注：

在运行之前，您需要将.mp3文件放到草图上。将其命名为“jingle.mp3”或将呼叫更改为loadFile()以使用正确的文件名

我以对数平均值为例。它们对于可视化而言比线性或根本没有平均值更有用。有关处理中声音可视化的FFT的更多有用提示，请参阅哥伦比亚大学教授的this answer和Dan Ellis' Music Signal Processing course（因为某些练习使用的是Processing的最小库）

如何使用最小化库为左右声道制作两个FFT对象进行处理

1 个答案: