Question

Idris标准库（或第三方库）中是否有一些模块允许一个程序转出另一个程序？我正在思考像Python subprocess和Haskell的System.Process这样的模块。

理想情况下，我希望以编程方式与流程进行交互（写入stdin，从stdout读取等）。

Answer 1

有system : String -> IO Int函数接受shell命令，运行它并返回其退出代码。您需要import System才能使用它：

import System

main : IO ()
main = do
  exitCode <- system "echo HelloWorld!"
  putStrLn $ "Exit code: " ++ show exitCode

  exitCode <- system "echo HelloWorld!; false"
  putStrLn $ "Exit code: " ++ show exitCode

在我的系统上，上面的代码产生以下输出：

HelloWorld!
Exit code: 0
HelloWorld!
Exit code: 256

我希望它在第二种情况下返回1而不是256。至少它是echo $?显示的内容。

可以基于Effects库制作另一个版本，this教程中对此进行了描述：

import Effects
import Effect.System
import Effect.StdIO

execAndPrint : (cmd : String) -> Eff () [STDIO, SYSTEM]
execAndPrint cmd = do
  exitCode <- system cmd
  putStrLn $ "Exit code: " ++ show exitCode

script : Eff () [STDIO, SYSTEM]
script = do
  execAndPrint "echo HelloWorld!"
  execAndPrint "sh -c \"echo HelloWorld!; exit 1\""

main : IO ()
main = run script

我们需要向Idris解释它需要Effects包：

idris -p effects <filename.idr>

我不知道任何Idris库可以让您轻松使用子进程的stdin / stdout。作为一种解决方法，我们可以使用C的管道工具，利用其popen / pclose函数，这些函数在Idris标准库中具有绑定。让我展示一下我们如何能够从子进程的stdout读取（请记住它是一个简单的基本错误处理片段）：

import System

-- read the contents of a file
readFileH : (fileHandle : File) -> IO String
readFileH h = loop ""
  where
    loop acc = do
      if !(fEOF h) then pure acc
      else do
        Right l <- fGetLine h | Left err => pure acc
        loop (acc ++ l)

execAndReadOutput : (cmd : String) -> IO String
execAndReadOutput cmd = do
  Right fh <- popen cmd Read | Left err => pure ""
  contents <- readFileH fh 
  pclose fh
  pure contents

main : IO ()
main = do
  out <- (execAndReadOutput "echo \"Captured output\"")
  putStrLn "Here is what we got:"
  putStr out

运行程序时，您应该看到

Here is what we got:
Captured output

如何在Idris中调用子流程？

1 个答案: