ESP8266上的多个从机SPI - PN532和ILI9341

时间：2016-09-24 15:18:55

标签： arduino esp8266 spi

我试图在相同的SPI总线上将ESP12-E模块与ILI9341显示器320 * 240和PN532 RFID阅读器连接起来。我在不同的GPIO上分配了SS Pins。

我无法与两者沟通。显示器可在任何条件下完美运行但是一旦我与ILI9341进行通信，PN532就会停止工作，直到我重新启动设备它才会响应。即使我重新初始化它。

任何帮助都会得到高度赞赏 我的代码：

#include <Wire.h>
#include <SPI.h>
#include <Adafruit_PN532.h>
#include <UTFT.h>
UTFT lcd(ILI9341_S5P,15,D1,D3);

// If using the breakout with SPI, define the pins for SPI communication.
#define PN532_SS   (D4)
#define PN532_SCK  (D5)
#define PN532_MOSI (D7)
#define PN532_MISO (D6)

// If using the breakout or shield with I2C, define just the pins connected
// to the IRQ and reset lines.  Use the values below (2, 3) for the shield!
#define PN532_IRQ   (2)
#define PN532_RESET (3)  // Not connected by default on the NFC Shield

// Uncomment just _one_ line below depending on how your breakout or shield
// is connected to the Arduino:

// Use this line for a breakout with a SPI connection:
Adafruit_PN532 nfc(PN532_SCK, PN532_MISO, PN532_MOSI, PN532_SS);

// Use this line for a breakout with a hardware SPI connection.  Note that
// the PN532 SCK, MOSI, and MISO pins need to be connected to the Arduino's
// hardware SPI SCK, MOSI, and MISO pins.  On an Arduino Uno these are
// SCK = 13, MOSI = 11, MISO = 12.  The SS line can be any digital IO pin.
//Adafruit_PN532 nfc(PN532_SS);

// Or use this line for a breakout or shield with an I2C connection:
//Adafruit_PN532 nfc(PN532_IRQ, PN532_RESET);
extern uint8_t BigFont[];

void setup(void) {
  Serial.begin(115200);
  Serial.println("Hello!");
  nfc.begin();

  uint32_t versiondata = nfc.getFirmwareVersion();
  if (! versiondata) {
    Serial.print("Didn't find PN53x board");
    while (1); // halt
  }

  // Got ok data, print it out!
  Serial.print("Found chip PN5"); Serial.println((versiondata>>24) & 0xFF, HEX); 
  Serial.print("Firmware ver. "); Serial.print((versiondata>>16) & 0xFF, DEC); 
  Serial.print('.'); Serial.println((versiondata>>8) & 0xFF, DEC);
  lcd.InitLCD();
    lcd.setColor ( 0, 0, 0 );
    lcd.fillRect(1,1,319,239);
    lcd.setColor ( 255, 255, 255 );
    lcd.fillRect(100,100,220,140);
  lcd.setFont ( BigFont );
  lcd.print(String("Scanning"),0,0);
  // Set the max number of retry attempts to read from a card
  // This prevents us from waiting forever for a card, which is
  // the default behaviour of the PN532.
  nfc.setPassiveActivationRetries(0xFF);

  // configure board to read RFID tags
  nfc.SAMConfig();

  Serial.println("Waiting for an ISO14443A card");
}

void loop(void) {
  boolean success;
  uint8_t uid[] = { 0, 0, 0, 0, 0, 0, 0 };  // Buffer to store the returned UID
  uint8_t uidLength;                // Length of the UID (4 or 7 bytes depending on ISO14443A card type)

  // Wait for an ISO14443A type cards (Mifare, etc.).  When one is found
  // 'uid' will be populated with the UID, and uidLength will indicate
  // if the uid is 4 bytes (Mifare Classic) or 7 bytes (Mifare Ultralight)
  success = nfc.readPassiveTargetID(PN532_MIFARE_ISO14443A, &uid[0], &uidLength,25);

  if (success) {
    Serial.println("Found a card!");
    Serial.print("UID Length: ");Serial.print(uidLength, DEC);Serial.println(" bytes");
    Serial.print("UID Value: ");
    for (uint8_t i=0; i < uidLength; i++) 
    {
      Serial.print(" 0x");Serial.print(uid[i], HEX); 
    }
    Serial.println("");
    // Wait 1 second before continuing
    delay(1000);
  }
  else
  {
    // PN532 probably timed out waiting for a card
    //Serial.println("Timed out waiting for a card");
  }
}

2 个答案:

答案 0 :(得分：0)

我对它进行了大量测试并发现 - SPI位顺序不同，因此您无法在同一SPI上驱动这两个器件。

但是你可以使用SW-SPI（bitbanging）作为NFC模块，因为没有必要快速驱动它。相反，TFT必须快速具有良好的更新速率。

我的设置仍然存在一个问题： 如果你有一个开放的串行终端，显示器没有显示内容。但是当它关​​闭时，TFT和NFC都能正常工作。

这是我的代码：

#include <ESP8266WiFi.h>
#include <Wire.h>
#include <SPI.h>
#include <Adafruit_PN532.h>
#include <UTFT.h>

// NFC module
#define PN532_SCK   D1
#define PN532_MOSI  D2
#define PN532_MISO  D3
#define PN532_SS    D0
Adafruit_PN532 nfc(PN532_SCK, PN532_MISO, PN532_MOSI, PN532_SS);

// TFT display
// HSPI defines
#define TFT_SCK     D5
#define TFT_MOSI    D7
//#define TFT_MISO    D6 (not connected)
#define TFT_CS      D8
#define TFT_DC      D4
UTFT myGLCD(ILI9341_S5P, TFT_CS, -1, TFT_DC);

// Declare which fonts we will be using
extern uint8_t SmallFont[];
extern uint8_t BigFont[];

// forward declaration of helper function to get UID as HEX-String
void byteToHexString(String &dataString, byte *uidBuffer, byte bufferSize, String strSeperator);

void setup() {
  Serial.begin(9600); 

  Serial.println("Initial nfc module");
  nfc.begin();
  uint32_t versiondata = nfc.getFirmwareVersion();
  if (! versiondata) {
    Serial.print("Didn't find PN53x board");
    while (1); // halt
  }

  // Got ok data, print it out!
  Serial.print("Found chip PN5"); Serial.println((versiondata>>24) & 0xFF, HEX); 
  Serial.print("Firmware ver. "); Serial.print((versiondata>>16) & 0xFF, DEC); 
  Serial.print('.'); Serial.println((versiondata>>8) & 0xFF, DEC);

  // Set the max number of retry attempts to read from a card
  // This prevents us from waiting forever for a card, which is
  // the default behaviour of the PN532.
  nfc.setPassiveActivationRetries(0xFF);

  // configure board to read RFID tags
  nfc.SAMConfig();

  Serial.println("Waiting for an ISO14443A card");
  Serial.println("Initial tft display");

  myGLCD.InitLCD();
  myGLCD.setColor(0, 0, 0);
  myGLCD.fillRect(1,1,319,239);
  myGLCD.setColor(255, 255, 255);
  myGLCD.setFont(BigFont);
  myGLCD.print(String("Scanning"),0,0);
}

void loop(void) {
  boolean success;
  uint8_t uid[] = { 0, 0, 0, 0, 0, 0, 0 };  // Buffer to store the returned UID
  uint8_t uidLength;                // Length of the UID (4 or 7 bytes depending on ISO14443A card type)

  // Wait for an ISO14443A type cards (Mifare, etc.).  When one is found
  // 'uid' will be populated with the UID, and uidLength will indicate
  // if the uid is 4 bytes (Mifare Classic) or 7 bytes (Mifare Ultralight)
  success = nfc.readPassiveTargetID(PN532_MIFARE_ISO14443A, uid, &uidLength);
  //success = nfc.readPassiveTargetID(PN532_MIFARE_ISO14443A, &uid[0], &uidLength,25);

  if (success) {
    Serial.println("Found a card!");
    Serial.print("UID Length: ");Serial.print(uidLength, DEC);Serial.println(" bytes");
    Serial.print("UID Value: ");
    String strUID;
    // store UID as HEX-String to strUID and print it to display
    byteToHexString(strUID, uid, uidLength, "-");
    Serial.println("");
    Serial.println(strUID);
    myGLCD.print(strUID, CENTER, 50);
    myGLCD.setColor ( 255, 0, 0 );
    myGLCD.setFont ( BigFont );
    myGLCD.print(String("Scanning"),0,0);
    // Wait 1 second before continuing
    delay(1000);
  }
  else
  {
    Serial.println("Timed out or waiting for a card");
  }
}

// helper function to get UID as HEX-String
void byteToHexString(String &dataString, byte *uidBuffer, byte bufferSize, String strSeperator=":") {
  dataString = "";
  for (byte i = 0; i < bufferSize; i++) {
    if (i>0) {
      dataString += strSeperator;
      if (uidBuffer[i] < 0x10)
        dataString += String("0");
    }
    dataString += String(uidBuffer[i], HEX);
  }
  dataString.toUpperCase();
}

答案 1 :(得分：0)

感谢您的帮助。 我不是一个喜欢SPI的大粉丝。 我尝试了几种方法并尝试重新初始化等。 最后，我解决了它。

我不知道为什么，但是当我在读卡后重新初始化spi硬件时，两个模块都能正常工作。

我在读卡后添加的代码：

    lcd._hw_special_init();

喜欢：

    success = nfc.readPassiveTargetID(PN532_MIFARE_ISO14443A, &uid[0], &uidLength,0);
    if (success) {
    lcd._hw_special_init();
    //Do the rest
    }
相关问题
最新问题