Question

gfortran现在有host_data支持，所以我想测试DGEMM。基于此处发布的测试用例

我使用cuBLAS为DGEMM编写了一个示例代码。

program test

  use iso_c_binding

  implicit none

  integer(c_int), parameter :: N = 10
  integer(c_int) :: i, j
  real(c_double) :: x(N, N), y(N, N), z(N, N)
  character(kind=c_char)     :: flag

  interface
     subroutine cublasdgemm(transa, transb, m, n, k, alpha, A, lda, B, &
             ldb, beta, C, ldc) bind(c, name="cublasDgemm")
       use iso_c_binding
       character(kind=c_char)     :: transa, transb
       integer(kind=c_int), value :: m, n, k
       real(c_double), value      :: alpha
       type(*), dimension(*)      :: A
       integer(kind=c_int), value :: lda
       type(*), dimension(*)      :: B
       integer(kind=c_int), value :: ldb
       real(c_double), value      :: beta
       type(*), dimension(*)      :: C
       integer(kind=c_int), value :: ldc

     end subroutine cublasdgemm

  end interface

  do i = 1, N
     do j = 1, N
       x(i, j) = 4.0 * i
       y(i, j) = 3.0 + j
       z(i, j) = 0.0
     end do
  end do

  flag = 'N'

  !$acc data copyin (x, y) copy (z)

  !$acc host_data use_device (x, y, z)
  call cublasdgemm(flag, flag, n, n, n, 1.0_c_double, x, n, y, n, 0.0_c_double, z, n)
  !$acc end host_data

  !$acc end data

  call dgemm(flag, flag, n, n, n, 1.0_c_double, x, n, y, n, 0.0_c_double, z, n)

  write(*, *) z

end program test

不幸的是我收到了这个错误。

** On entry to DGEMM  parameter number 1 had an illegal value

在我看来，字符数据类型存在一些不匹配。但我无法弄明白。我在最后使用相同的变量调用DGEMM调用，它完美地工作。

感谢您的帮助。

编译：

为了编译这个，我使用基于此链接说明编译的gfortran 6.2

gfortran with nvptx

然后我从

复制

/usr/local/cuda/src/

文件

fortran_common.h
fortran.h
fortran.c

然后再做

gcc -Wall -g -I/usr/local/cuda/include -I/usr/local/cuda/src -DCUBLAS_GFORTRAN -c fortran.c

获取cuBLAS接口的fortran.o文件。

然后我做

gfortran -Wall -g test.f90 fortran.o -fopenacc -foffload=nvptx-none -foffload=-O3 -O3 -o gpu.x -L/usr/local/cuda/lib64 -lcublas -lcudart -lblas

这是我用来在第一个链接中成功运行saxpy示例的过程。

Answer 1

原来答案很简单。我不得不添加＆＃34;值＆＃34;到字符变量的定义。

    subroutine cublasdgemm(transa, transb, m, n, k, alpha, A, lda, B, &
             ldb, beta, C, ldc) bind(c, name="cublasDgemm")
       use iso_c_binding
       character(kind=c_char), value     :: transa, transb
       integer(kind=c_int), value :: m, n, k
       real(c_double), value      :: alpha
       type(*), dimension(*)      :: A
       integer(kind=c_int), value :: lda
       type(*), dimension(*)      :: B
       integer(kind=c_int), value :: ldb
       real(c_double), value      :: beta
       type(*), dimension(*)      :: C
       integer(kind=c_int), value :: ldc

     end subroutine cublasdgemm

在gfortran中使用DGEMM调用错误的OpenACC

1 个答案: