Question

我经常有一个由另一个类列表组成的类。例如，我将有一个由向量组成的向量列表类。为了避免编写长语句，我编写了一个访问嵌入式类的方法。但是，这种方法只起吸气剂的作用;我不能用它来设置插槽值。有没有办法使用方法来设置类槽值？

以下是一个最小的例子：

(defclass vector ()
  ((name :accessor vector-name
         :initarg :name)))

(defclass vector-list ()
  ((vectors :accessor vector-list-vectors
            :initarg :vectors)))

(defun make-vector-list ()
  (make-instance 'vector-list
    :vectors (list
               (make-instance 'vector :name 'v1)
               (make-instance 'vector :name 'v2))))

(defmethod access-vector-name ((vt vector-list) vector-idx)
  (vector-name (nth vector-idx (vector-list-vectors vt))))


;; returns V1
(print (access-vector-name (make-vector-list) 0))

;; Now, trying to set the same slot returns an error
;; How can I set the slot?
(setf (access-vector-name (make-vector-list) 0) 'new); --> error

Answer 1

最简单的是写：

(setf (aref (access-vector-name ...) index) value)`

但是如果你不想揭露你有数组/向量的事实，你可以定义一个自定义的setf扩展器。

首先，只在您的班级中将access-vector-name定义为:reader。然后：

(defun (setf access-vector-name) (newval obj index)
  (setf (aref (access-vector-name obj) index) newval))

如果目的是隐藏底层实现，那么access-vector-name可能是一个坏名称。

Answer 2

您只需要定义一个setter方法来执行此操作。但是，您的代码不合法：VECTOR是CL包中的已定义符号（实际上同时命名了一个函数和一个类型），因此定义一个名为VECTOR的类是可怕的非法（和一个体面的实施将在这个barf）。以下是代码的一个版本，其基本类已重命名为VEC，并使用setter方法。

(defclass vec ()
  ;; Don't call it VECTOR since it's a function in CL
  ((name :accessor vec-name
         :initarg :name)))

(defclass vec-list ()
  ((vecs :accessor vec-list-vecs
         :initarg :vecs)))

(defun make-vec-list ()
  (make-instance 'vec-list
    :vecs (list
           (make-instance 'vec :name 'v1)
           (make-instance 'vec :name 'v2))))

(defmethod access-vec-name ((vt vec-list) vec-idx)
  (vec-name (nth vec-idx (vec-list-vecs vt))))

(defmethod (setf access-vec-name) (new (vt vec-list) vec-idx)
  (setf (vec-name (nth vec-idx (vec-list-vecs vt))) new))

CLOS没有一个预定义的宏来定义这样的访问者方法，在类定义之外：我不确定为什么，但也许是因为它真的是纯粹的＆＃ 39;像这样的访问者相对不常见。

Common Lisp中的类的getter和setter

2 个答案: