Question

这是C＃中的一个简单生成器。

    IEnumerable<int> Foo()
    {
        int a = 1, b = 1;
        while(true)
        {
            yield return b;
            int temp = a + b;
            a = b;
            b = temp;
        }
    }

如何在 Digital Mars D？

中编写类似的生成器

（问题是关于产量回报声明）

谢谢！

更新。那很有意思。由于我只是生成数学序列，因此使用recurrence可能是一个不错的选择。

auto fib = recurrence!("a[n-1] + a[n-2]")(1, 1);

foreach (e; take(fib, 10)) // <- prints first ten numbers from the sequence
{ 
    writeln(e); 
}

Answer 1

D中没有精确等价物。这里有一些粗略的等价物：

使用opApply样式的内部迭代。但是，这不允许以锁步方式迭代两个迭代器：

struct Foo {
    int opApply(int delegate(ref int) dg) {
        int a = 1, b = 1;
        int result;
        while(true) {
            result = dg(b);
            if(result) break;
            int temp = a + b;
            a = b;
            b = temp;
        }

        return result;
    }
}

void main() {
    // Show usage:
    Foo foo;
    foreach(elem; foo) {
        // Do stuff.
    }
}

使用范围。在某些情况下，这些写入稍微困难一些，但效率非常高并且允许锁步迭代。这也可以使用foreach循环进行迭代，与opApply版本完全相同：

struct Foo {
    int a = 1, b = 1;

    int front() @property {
        return b;
    }

    void popFront() {
        int temp = a + b;
        a = b;
        b = temp;
    }

    // This range is infinite, i.e. never empty.
    enum bool empty = false;

    typeof(this) save() @property { return this; }
}

如果你真的需要协程式的东西，你可以使用core.thread.Fiber将范围和opApply组合在一起，但你可能会发现范围或opApply几乎所有你需要的东西时间。

Answer 2

见here;示例摘录如下：

module main;

import std.stdio;
import generators;

void genSquares(out int result, int from, int to)
{
    foreach (x; from .. to + 1)
        yield!result(x * x);
}

void main(string[] argv)
{
    foreach (sqr; generator(&genSquares, 10, 20))
        writeln(sqr);
}

Answer 3

std.concurrency模块现在有一个Generator课程，这使得这更容易（并且您不需要第三方库）。

该类是一个输入范围，因此它可以与for循环和所有标准std.range / std.algorithm函数一起使用。

import std.stdio;
import std.range;
import std.algorithm;
import std.concurrency : Generator, yield;

void main(string[] args) {
    auto gen = new Generator!int({
        foreach(i; 1..10)
            yield(i);
    });

    gen
        .map!(x => x*2)
        .each!writeln
    ;
}

什么是D编程语言中的“收益率”等价物？

3 个答案: