Question

我有一个包含字符和实数的矩阵，我想要一个读取此矩阵的程序（自己查找尺寸）。这是我的代码：

! A fortran95 program for G95
Program Project2nd
implicit none
character(len=40), allocatable :: a(:,:)
integer i,j,k,n,m,l,st
character(len=40) d
n=0; m=1; j=1;

open(10,file=&
 '/Users/dariakowsari/Documents/Physics/Programming/Fortran95-Projects/Project2nd/input.txt', &
   IOstat=st)

do while (st == 0)
   read(10,*,IOstat=st) d
   n=n+1
end do

st=0
do j=1,m
  do while (st == 0)
     allocate(a(1,m))
        read(10,*,IOstat=st) (a(1,j),j=1,m)
          m=m+1
         deallocate(a)
 end do

 print*, n,m


end

这是我的矩阵：

a   b   13   15.5   13.2
c   d   16   16.75  19
e   f   19.2 12.2   18.2

使用这段代码我得到（3,2）矩阵的维度。

Answer 1

您的示例代码中存在一些错误，这意味着它不会为我编译，但经过一些更改后，我设法得到了类似的结果。 * 更新：正如@francescalus在对我的其他（现已删除）答案的评论中所指出的那样，该方法涉及未定义的行为，因此不是一个合适的解决方案。这是因为尝试从文件中读取的元素多于存在的元素。）

这是一种替代方法，应该避免这种未定义的行为，但可能效率很低。

Program Project2nd
  implicit none
  character(len=40), allocatable :: a(:)
  integer, allocatable :: ind(:)
  integer, parameter :: maxElements = 100
  integer i,j,n,m,st
  character(len=40) d
  n=0;

  open(10,file='mat.txt',IOstat=st)
  !Find number of lines
  do while (st == 0)
     read(10,*,IOstat=st) d
     if(st ==0) n=n+1
  end do
  !Move back to the start of the file
  rewind(10)

  !Read all of the data
  do m=n,maxElements,n
     allocate(a(m))
     read(10,*,IOstat=st) a
     deallocate(a)
     rewind(10)
     if(st.ne.0) exit
  enddo
  m = m -n !Need to roll back m by one iteration to get the last which worked.
  if(mod(m,n).ne.0) then
     print*,"Error: Number of elements not divisible by number of rows."
     stop
  endif
  !Number of columns = n_elements/nrow
  m=m/n
  print*, n,m
end Program Project2nd

本质上，它使用与计算行数相同的代码，但请注意，您只想在读取成功时增加n（即st == 0）。注意，一旦st变为非零，我们就不会退出while块，只有一旦我们到达while块的末尾。之后，我们需要回放文件，以便下一次读取从文件的开头开始。

在之前的评论中，您提到如果您真的想要避免这种情况，则不必指定maxElement，然后用

之类的内容替换第二个do循环

  st = 0 ; m = n
  do while (st==0)
     allocate(a(m))
     read(10,*,IOstat=st) a
     deallocate(a)
     rewind(10)
     if(st.ne.0) then
       m = m - n !Go back to value of m that worked            
       exit
     endif
     m=m+n
  enddo

Answer 2

这里是如何进行无倒带。

  implicit none
  character(len=100) wholeline
  character(len=20), allocatable :: c(:)
  integer iline,io,ni,nums
  open(20,file='testin.dat')
  iline=0
  do while(.true.)
     read(20,'(a)',iostat=io)wholeline
     if(io.ne.0)exit
     iline=iline+1
     ni=lineitems(wholeline)
     allocate(c(ni))
     read(wholeline,*)c
     nums=ctnums(c)
     write(*,*)'line',iline,' contains ',ni,'items',nums,
 $        'are numbers'
     deallocate(c)
  enddo
  write(*,*)'total lines is ',iline
  contains

  integer function ctnums(c)
  ! count the number of items in a character array that are numbers
  ! this is a template,
  ! obviously you could assign the numbers to a real array here
  character(len=*), allocatable :: c(:)      
  real f
  integer i,io
  ctnums=0
  do i = 1,size(c)
     read(c(i),*,iostat=io)f
     if(io.eq.0)ctnums=ctnums+1
  enddo
  end function

  integer function lineitems(line)
  ! count the number of items in a space delimited string
  integer,parameter ::maxitems=100
  character(len=*) line
  character(len=80) :: c(maxitems)
  integer iline,io
  lineitems=0
  do iline=1,maxitems
     read(line,*,iostat=io)c(:iline)
     if(io.ne.0)return
     lineitems=iline
  enddo
  if(lineitems.eq.maxitems)write(*,*)'warning maxitems reached'
  end function
  end

输出

line 1 contains 5 items 3 are numbers
line 2 contains 5 items 3 are numbers
total lines is 2

如何找到矩阵的维数？

2 个答案: